m4/charybdis.m4

   1 AC_DEFUN([AC_DEFINE_DIR], [
   2   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
   3   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
   4   last_ac_define_dir=`eval echo [$]$2`
   5   ac_define_dir=`eval echo [$]last_ac_define_dir`
   6   ac_define_dir_counter=0
   7   while test "x[$]last_ac_define_dir" != "x[$]ac_define_dir"; do
   8     last_ac_define_dir="[$]ac_define_dir"
   9     ac_define_dir=`eval echo [$]last_ac_define_dir`
  10     AS_VAR_ARITH([ac_define_dir_counter], [$ac_define_dir_counter + 1])
  11     AS_VAR_IF([ac_define_dir_counter], [128],
  12         [AC_MSG_ERROR([detected recusive directory expansion when expanding $1=[$]$2: [$]ac_define_dir])
  13         break])
  14   done
  15   $1="$ac_define_dir"
  16   AC_SUBST($1)
  17   ifelse($3, ,
  18     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
  19     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
  20 ])
  21
  22 AC_DEFUN([AC_SUBST_DIR], [
  23         ifelse($2,,,$1="[$]$2")
  24         $1=`(
  25             test "x$prefix" = xNONE && prefix="$ac_default_prefix"
  26             test "x$exec_prefix" = xNONE && exec_prefix="${prefix}"
  27             eval echo \""[$]$1"\"
  28         )`
  29         AC_SUBST($1)
  30 ])
  31
  32 dnl SOLANUM_C_GCC_TRY_FLAGS(<warnings>,<cachevar>)
  33 AC_DEFUN([SOLANUM_C_GCC_TRY_FLAGS],[
  34  AC_MSG_CHECKING([GCC flag(s) $1])
  35  if test "${GCC-no}" = yes
  36  then
  37   AC_CACHE_VAL($2,[
  38    oldcflags="${CFLAGS-}"
  39    CFLAGS="${CFLAGS-} ${CWARNS} $1 -Werror"
  40    AC_TRY_COMPILE([
  41 #include <string.h>
  42 #include <stdio.h>
  43 int main(void);
  44 ],[
  45     (void)strcmp("a","b"); fprintf(stdout,"test ok\n");
  46 ], [$2=yes], [$2=no])
  47    CFLAGS="${oldcflags}"])
  48   if test "x$$2" = xyes; then
  49    CWARNS="${CWARNS}$1 "
  50    AC_MSG_RESULT(ok)
  51   else
  52    $2=''
  53    AC_MSG_RESULT(no)
  54   fi
  55  else
  56   AC_MSG_RESULT(no, not using GCC)
  57  fi
  58 ])