configure.ac

   1 dnl TODO: clean up all the OpenSSL and shared module checking stuff;
   2 dnl the most major changes have already been made and it looks like
   3 dnl said functions need to be just about as complex as they already are.
   4
   5 AC_PREREQ(2.60)
   6
   7 AC_INIT([charybdis], [4.1-dev])
   8
   9 AC_LANG(C)
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_GNU_SOURCE
  12
  13 AC_PROG_CC_C99
  14
  15 if test x"$ac_cv_prog_cc_c99" = "xno"; then
  16         AC_ERROR([charybdis requires a C99 capable compiler])
  17 fi
  18
  19 AC_PREFIX_DEFAULT($HOME/ircd)
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_HEADER(include/setup.h)
  22
  23 AC_CONFIG_SUBDIRS([librb])
  24 AC_CONFIG_AUX_DIR([libltdl/config])
  25
  26 AM_INIT_AUTOMAKE([subdir-objects])
  27 AM_SILENT_RULES([yes])
  28 AM_PROG_AR
  29
  30 LT_INIT([dlopen disable-static])
  31 LT_CONFIG_LTDL_DIR([libltdl])
  32 LTDL_INIT
  33
  34 build_ltdl=$with_included_ltdl
  35 AM_CONDITIONAL([BUILD_LTDL], [test x"$build_ltdl" = x"yes"])
  36
  37 case "$host_os" in
  38 *cygwin*)
  39      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
  40      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  41      ;;
  42 *mingw* | *msys*)
  43      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
  44      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  45      AC_CHECK_HEADER(winsock2.h, , [AC_MSG_ERROR([** MinGW and no winsock2.h.  I give up.])])
  46      LIBS="$LIBS -lws2_32 -liphlpapi"
  47      is_mingw="yes"
  48      ;;
  49 *)
  50      ;;
  51 esac
  52
  53 AM_CONDITIONAL([MINGW], [test "$is_mingw" = "yes"])
  54
  55 if test "$ac_cv_c_compiler_gnu" = yes; then
  56         IRC_CFLAGS="$IRC_CFLAGS -O0 -Wall"
  57 fi
  58
  59 dnl If we support -g, use it!
  60 if test "$ac_cv_prog_cc_g" = yes; then
  61         IRC_CFLAGS="$IRC_CFLAGS -g"
  62 fi
  63
  64 dnl check for /dev/null so we can use it to hold evil fd's
  65 AC_MSG_CHECKING([for /dev/null])
  66 if test -c /dev/null ; then
  67         AC_DEFINE(PATH_DEVNULL, "/dev/null", [Path to /dev/null])
  68         AC_MSG_RESULT(yes)
  69 else
  70         AC_DEFINE(PATH_DEVNULL, "devnull.log", [Path to /dev/null])
  71         AC_MSG_RESULT(no - using devnull.log)
  72 fi
  73
  74 dnl jdc -- If CFLAGS is defined, best use it everywhere...
  75 dnl NOTE: jv says it must be added to the *END*, because things like
  76 dnl "gcc -O9 -O2" will result in -O2 getting preference.  How stupid.
  77 if test ! -z "$CFLAGS"; then
  78         IRC_CFLAGS="$IRC_CFLAGS $CFLAGS"
  79 fi
  80
  81 AC_ISC_POSIX
  82 AC_C_INLINE
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PATH_PROG(RM, rm)
  86 AC_PATH_PROG(CP, cp)
  87 AC_PATH_PROG(MV, mv)
  88 AC_PATH_PROG(LN, ln)
  89 AC_PATH_PROG(SED, sed)
  90 AC_PATH_PROG(AR, ar)
  91 AC_PATH_PROG(LD, ld)
  92 AC_PATH_PROG(RANLIB, ranlib)
  93 AC_PATH_PROG(TOUCH, touch)
  94
  95 AC_PROG_YACC
  96
  97 dnl AC_PROG_YACC defaults to yacc unconditionally if nothing can be found
  98 if test "$YACC" = "yacc" -a -z "`which $YACC 2>/dev/null`"; then
  99         AC_MSG_ERROR([could not locate a suitable parser generator; install bison, yacc, or byacc])
 100 fi
 101
 102 AC_PROG_LEX
 103
 104 if test "$LEX" = ":"; then
 105         AC_MSG_ERROR([could not locate a suitable lexical generator, install flex or lex.])
 106 fi
 107
 108 AC_ARG_ENABLE([fhs-paths],
 109         [AS_HELP_STRING([--enable-fhs-paths], [Use more FHS-like pathnames (for packagers).])],
 110         [],
 111         [dnl detect if the user appears to want --enable-fhs-paths
 112         AS_IF([test "$libexecdir" = '${exec_prefix}/libexec' && \
 113                 test "$localstatedir" = '${prefix}/var' && \
 114                 test "$libdir" = '${exec_prefix}/lib'],
 115                 [enable_fhs_paths=no],
 116                 [enable_fhs_paths=yes])
 117         ])
 118 dnl use directory structure of cached as default (hack)
 119 AS_IF([test "x$enable_fhs_paths" = "xyes"],
 120         [dnl Avoid name collisions.
 121         pkglibexecdir='${libexecdir}/${PACKAGE_TARNAME}'
 122         rundir=${rundir-'${prefix}/run'}
 123         pkgrundir='${rundir}/${PACKAGE_TARNAME}'
 124         pkglocalstatedir='${localstatedir}/${PACKAGE_TARNAME}'
 125         AC_DEFINE([ENABLE_FHS_PATHS], [1], [Uncomment if FHS pathnames are enabled])],
 126         [libexecdir='${bindir}'
 127         pkglibexecdir='${libexecdir}'
 128         rundir='${sysconfdir}'
 129         pkgrundir='${rundir}'
 130         localstatedir='${prefix}'
 131         pkglocalstatedir='${sysconfdir}'])
 132 pkglibdir='${libdir}/${PACKAGE_TARNAME}'
 133 AC_SUBST([pkglibdir])
 134 AC_SUBST([rundir])
 135 AC_SUBST([pkgrundir])
 136 AC_SUBST([pkglocalstatedir])
 137 AC_DEFINE_DIR([PKGLOCALSTATEDIR], [pkglocalstatedir], [[Directory in which to store state, such as ban database]])
 138 AC_SUBST([pkglibexecdir])
 139 AC_DEFINE_DIR([PKGLIBEXECDIR], [pkglibexecdir], [Directory where binaries the IRCd itself spawns live])
 140
 141 dnl Checks for header files.
 142 AC_HEADER_STDC
 143 AC_HEADER_STDBOOL
 144
 145 AC_CHECK_HEADERS([crypt.h sys/resource.h sys/param.h errno.h sys/syslog.h stddef.h sys/wait.h wait.h sys/epoll.h sys/uio.h machine/endian.h])
 146
 147 dnl Stuff that the memory manager (imalloc) depends on
 148 dnl ==================================================
 149
 150 AC_C_CONST
 151 if test "$ac_cv_header_machine_endian_h" = "no" ; then
 152     AC_C_BIGENDIAN
 153 fi
 154 AC_TYPE_PID_T
 155 AC_TYPE_SIZE_T
 156 AC_CHECK_SIZEOF(short)
 157 AC_CHECK_SIZEOF(int)
 158 AC_CHECK_SIZEOF(long)
 159 AC_CHECK_SIZEOF(long long)
 160
 161 dnl Networking Functions
 162 dnl ====================
 163
 164 AC_SEARCH_LIBS(socket, [socket ws2_32], , [AC_MSG_ERROR([You have no socket()! Aborting.])])
 165
 166 dnl SunOS/Solaris required libnsl for inet_ntoa()
 167 if test x"$SUN" = xyes; then
 168         AC_SEARCH_LIBS(inet_ntoa, nsl,, [AC_MSG_ERROR([libnsl not found! Aborting.])])
 169 fi
 170
 171 AC_SEARCH_LIBS(crypt, [crypt descrypt],,)
 172
 173 CRYPT_LIB=$ac_cv_search_crypt
 174
 175 if test "$CRYPT_LIB" = "none required"; then
 176         unset CRYPT_LIB
 177 elif test "$CRYPT_LIB" = no; then
 178         unset CRYPT_LIB
 179 fi
 180
 181 AC_SUBST(CRYPT_LIB)
 182
 183 AC_C_BIGENDIAN
 184
 185 dnl Check for stdarg.h - if we can't find it, halt configure
 186 AC_CHECK_HEADER(stdarg.h, , [AC_MSG_ERROR([** stdarg.h could not be found - charybdis will not compile without it **])])
 187 AC_CHECK_FUNCS([strlcat strlcpy])
 188
 189 AC_TYPE_INT16_T
 190 AC_TYPE_INT32_T
 191
 192 AC_CHECK_TYPE([sa_family_t], [],
 193 [AC_DEFINE(sa_family_t, [u_int16_t], [If system does not define sa_family_t, define it here.])],
 194 [[#include <sys/types.h>
 195 #include <sys/socket.h>]])
 196
 197 AC_CHECK_TYPES([uintptr_t])
 198
 199 dnl check for various functions...
 200 AC_CHECK_FUNCS([snprintf vsnprintf socketpair mmap gettimeofday strdup strndup ])
 201
 202 AC_FUNC_ALLOCA
 203
 204 dnl Specialized functions checks
 205 dnl ============================
 206
 207 dnl check for nanosleep
 208 AC_CHECK_FUNC(nanosleep,,[AC_CHECK_LIB(rt,nanosleep,
 209                  LIBS="${LIBS} -lrt",
 210                  [AC_CHECK_LIB(posix4,nanosleep, LIBS="${LIBS} -lposix4"
 211                  )])])
 212 if test x$ac_cv_func_nanosleep = xno && test x$ac_cv_lib_posix4_nanosleep = xno  && test x$ac_cv_lib_rt_nanosleep = xno
 213 then
 214          AC_MSG_RESULT("nanosleep not found..using select for delay")
 215 else
 216          AC_DEFINE([HAVE_NANOSLEEP], 1, [Define if nanosleep exists])
 217 fi
 218
 219 dnl OpenSSL support
 220 AC_MSG_CHECKING(for OpenSSL)
 221 AC_ARG_ENABLE(openssl,
 222 [AC_HELP_STRING([--enable-openssl[=DIR]],[Enable OpenSSL support (DIR optional).])
 223 AC_HELP_STRING([--disable-openssl],[Disable OpenSSL support.])],
 224 [cf_enable_openssl=$enableval],
 225 [cf_enable_openssl="auto"])
 226
 227 if test "$cf_enable_openssl" != "no" ; then
 228         cf_openssl_basedir=""
 229         if test "$cf_enable_openssl" != "auto" &&
 230         test "$cf_enable_openssl" != "yes" ; then
 231                 dnl Support for --enable-openssl=/some/place
 232                 cf_openssl_basedir="`echo ${cf_enable_openssl} | sed 's/\/$//'`"
 233         else
 234         dnl Do the auto-probe here.  Check some common directory paths.
 235                 for dirs in /usr/local/ssl /usr/pkg /usr/local \
 236                 /usr/local/openssl ; do
 237                         if test -f "${dirs}/include/openssl/opensslv.h" ; then
 238                                 cf_openssl_basedir="${dirs}"
 239                         break
 240                         fi
 241                 done
 242                 unset dirs
 243         fi
 244         dnl Now check cf_openssl_found to see if we found anything.
 245         if test ! -z "$cf_openssl_basedir"; then
 246                 if test -f "${cf_openssl_basedir}/include/openssl/opensslv.h" ; then
 247                         SSL_INCLUDES="-I${cf_openssl_basedir}/include"
 248                         SSL_LIBS="-L${cf_openssl_basedir}/lib"
 249                 else
 250                 dnl OpenSSL wasn't found in the directory specified.  Naughty
 251                 dnl administrator...
 252                 cf_openssl_basedir=""
 253                 fi
 254         else
 255         dnl Check for stock FreeBSD 4.x and 5.x systems, since their files
 256         dnl are in /usr/include and /usr/lib.  In this case, we don't want to
 257         dnl change INCLUDES or LIBS, but still want to enable OpenSSL.
 258         dnl We can't do this check above, because some people want two versions
 259         dnl of OpenSSL installed (stock FreeBSD 4.x/5.x and /usr/local/ssl)
 260         dnl and they want /usr/local/ssl to have preference.
 261                 if test -f "/usr/include/openssl/opensslv.h" ; then
 262                         cf_openssl_basedir="/usr"
 263                 fi
 264         fi
 265
 266         dnl If we have a basedir defined, then everything is okay.  Otherwise,
 267         dnl we have a problem.
 268         if test ! -z "$cf_openssl_basedir"; then
 269                 AC_MSG_RESULT($cf_openssl_basedir)
 270                 cf_enable_openssl="yes"
 271         else
 272                 AC_MSG_RESULT([not found. Specify a correct path?])
 273                 cf_enable_openssl="no"
 274         fi
 275         unset cf_openssl_basedir
 276 else
 277         dnl If --disable-openssl was specified
 278         AC_MSG_RESULT(disabled)
 279 fi
 280
 281 save_CPPFLAGS="$CPPFLAGS"
 282 CPPFLAGS="$CPPFLAGS $SSL_INCLUDES"
 283 save_LIBS="$LIBS"
 284 LIBS="$LIBS $SSL_LIBS"
 285 if test "$cf_enable_openssl" != no; then
 286         dnl Check OpenSSL version (must be 0.9.6 or above!)
 287         AC_MSG_CHECKING(for OpenSSL 0.9.6 or above)
 288         AC_RUN_IFELSE(
 289                 [AC_LANG_PROGRAM(
 290                 [#include <openssl/opensslv.h>
 291                 #include <stdlib.h>],
 292                 [[if ( OPENSSL_VERSION_NUMBER >= 0x00906000)
 293                 exit(0); else exit(1);]])],
 294         cf_openssl_version_ok=yes,
 295         cf_openssl_version_ok=no,
 296         cf_openssl_version_ok=no)
 297
 298         if test "$cf_openssl_version_ok" = yes; then
 299                 AC_MSG_RESULT(found)
 300
 301                 dnl Work around pmake/gmake conditional incompatibilities
 302                 AC_SUBST(ENCSPEED, encspeed)
 303
 304                 dnl Do all the HAVE_LIBCRYPTO magic -- and check for ciphers
 305                 CPPFLAGS="$CPPFLAGS $SSL_LIBS"
 306                 AC_CHECK_LIB(crypto, RSA_free)
 307                 SSL_LIBS="$SSL_LIBS -lcrypto"
 308                 SSL_SRCS_ENABLE='$(SSL_SRCS)'
 309         else
 310                 AC_MSG_RESULT(no - OpenSSL support disabled)
 311         fi
 312 fi
 313
 314 CPPFLAGS="$save_CPPFLAGS"
 315 LIBS="$save_LIBS"
 316
 317 dnl End OpenSSL detection
 318
 319
 320 dnl Specialized functions and libraries
 321 dnl ===================================
 322
 323 AC_ARG_WITH(zlib-path,
 324 AC_HELP_STRING([--with-zlib-path=DIR],[Path to libz.so for ziplinks support.]),
 325 [LIBS="$LIBS -L$withval"],)
 326
 327 AC_ARG_ENABLE(zlib,
 328 AC_HELP_STRING([--disable-zlib],[Disable ziplinks support]),
 329 [zlib=$enableval],[zlib=yes])
 330
 331 if test "$zlib" = yes; then
 332
 333 AC_CHECK_HEADER(zlib.h, [
 334         AC_CHECK_LIB(z, zlibVersion,
 335         [
 336                 AC_SUBST(ZLIB_LD, -lz)
 337                 AC_DEFINE(HAVE_LIBZ, 1, [Define to 1 if zlib (-lz) is available.])
 338         ], zlib=no)
 339 ], zlib=no)
 340
 341 fi
 342
 343 dnl Check for shared sqlite
 344 dnl ======================
 345 AC_ARG_WITH(shared-sqlite,
 346 AC_HELP_STRING([--with-shared-sqlite],[Use shared sqlite]),
 347 [shared_sqlite=$withval],[shared_sqlite=no])
 348
 349 if test "$shared_sqlite" = yes; then
 350         PKG_CHECK_MODULES(SQLITE, [sqlite3],
 351         [
 352                 shared_sqlite=yes
 353         ], shared_sqlite=no)
 354 fi
 355
 356 if test "$shared_sqlite" = no; then
 357         SQLITE_OBJ='sqlite3.$(OBJEXT)'
 358 fi
 359
 360 AC_SUBST(SQLITE_LD, "$SQLITE_LIBS")
 361 AC_SUBST(SQLITE_INCLUDES, "$SQLITE_CFLAGS")
 362 AC_SUBST(SQLITE_OBJ)
 363
 364 dnl **********************************************************************
 365 dnl Check for --with-confdir [deprecated, use --sysconfdir instead]
 366 dnl **********************************************************************
 367
 368 AC_ARG_WITH([confdir],
 369         [AC_HELP_STRING([--with-confdir=DIR],
 370                [Directory to install config files [deprecated, use --sysconfdir instead].])],
 371         [ sysconfdir=`echo $withval | sed 's/\/$//'` ],
 372         [ confdir='${sysconfdir}' ])
 373 AC_DEFINE_DIR([ETC_DIR], [sysconfdir], [Prefix where config files are installed.])
 374
 375 dnl **********************************************************************
 376 dnl Check for --with-logdir
 377 dnl **********************************************************************
 378
 379 AC_MSG_CHECKING([whether to modify logdir])
 380 AC_ARG_WITH(logdir,
 381 AC_HELP_STRING([--with-logdir=DIR],
 382                [Directory where to write logfiles.]),
 383                [ logdir=`echo $withval | sed 's/\/$//'`
 384                  AC_MSG_RESULT(yes)],
 385                [ AS_IF([test "x$enable_fhs_paths" = "xyes"],
 386                         [logdir='${localstatedir}/log/${PACKAGE_TARNAME}'],
 387                         [logdir='${prefix}/logs'])
 388                  AC_MSG_RESULT(no)])
 389 AC_DEFINE_DIR([LOG_DIR], [logdir], [Prefix where to write logfiles.])
 390 AC_SUBST_DIR([logdir])
 391
 392 dnl **********************************************************************
 393 dnl Check for --with-helpdir
 394 dnl **********************************************************************
 395
 396 AC_MSG_CHECKING([whether to modify helpdir])
 397 AC_ARG_WITH(helpdir,
 398 AC_HELP_STRING([--with-helpdir=DIR],
 399                [Directory to install help files.]),
 400                [ helpdir=`echo $withval | sed 's/\/$//'`
 401                  AC_MSG_RESULT(yes) ],
 402                [ AS_IF([test "x$enable_fhs_paths" = "xyes"],
 403                         [helpdir='${datadir}/${PACKAGE_TARNAME}/help'],
 404                         [helpdir='${prefix}/help'])
 405                  AC_MSG_RESULT(no) ])
 406 AC_DEFINE_DIR([HELP_DIR], [helpdir], [Prefix where help files are installed.])
 407 AC_SUBST_DIR([helpdir])
 408
 409 dnl **********************************************************************
 410 dnl Check for --with-moduledir
 411 dnl **********************************************************************
 412
 413 AC_MSG_CHECKING([whether to modify moduledir])
 414 AC_ARG_WITH(moduledir,
 415         [AC_HELP_STRING([--with-moduledir=DIR],
 416                [Directory to install modules.])],
 417                [ moduledir=`echo $withval | sed 's/\/$//'`
 418                  AC_MSG_RESULT(yes)],
 419                [ AS_IF([test "x$enable_fhs_paths" = "xyes"],
 420                         [moduledir='${pkglibdir}/modules'],
 421                         [moduledir='${prefix}/modules'])
 422                  AC_MSG_RESULT(no)
 423                 ])
 424 AC_DEFINE_DIR(MODULE_DIR, moduledir, [Prefix where modules are installed.])
 425 AC_SUBST_DIR([moduledir])
 426
 427 dnl Check for --with-rundir
 428
 429 AC_MSG_CHECKING([whether or modify rundir])
 430 AC_ARG_WITH([rundir],
 431         [AC_HELP_STRING([--with-rundir=DIR],
 432                 [Directory in which to store pidfile.])],
 433         [AC_MSG_RESULT([yes])
 434         rundir=`echo $withval | sed 's/\/$//'`],
 435         [AC_MSG_RESULT([no])
 436         AS_IF([test "x$enable_fhs_paths" = "xyes"],
 437                 [rundir='${prefix}/run'],
 438                 [rundir='${sysconfdir}'])])
 439 AC_SUBST([rundir])
 440 AC_DEFINE_DIR([PKGRUNDIR], [pkgrundir], [Directory to store pidfile in.])
 441
 442 dnl Installed utility program prefixes (does not affect binaries
 443 dnl installed into pkglibexecdir)
 444 AC_MSG_CHECKING([for program prefix])
 445 AC_ARG_WITH([program-prefix],
 446         [AS_HELP_STRING([--with-program-prefix=], [If set, programs installed into PATH will be installed with names prefixed by this prefix.])],
 447         [test "x$with_program_prefix" = "xno" && with_program_prefix=],
 448         [with_program_prefix=])
 449 AC_MSG_RESULT(["$with_program_prefix"])
 450 PROGRAM_PREFIX="$with_program_prefix"
 451 AC_SUBST([PROGRAM_PREFIX])
 452 AC_DEFINE_UNQUOTED([PROGRAM_PREFIX], ["$with_program_prefix"], [String with which all programs intended to be in PATH are prefixed.])
 453
 454 dnl **********************************************************************
 455 dnl Branding
 456 dnl **********************************************************************
 457
 458 AC_MSG_CHECKING([whether custom branding is requested])
 459 AC_ARG_WITH(custom-branding,
 460 AC_HELP_STRING([--with-custom-branding=NAME],
 461                [Custom branding name.]),
 462                [BRANDING_NAME=$withval
 463                 AC_MSG_RESULT([yes])],
 464                [BRANDING_NAME=$PACKAGE_NAME
 465                 AC_MSG_RESULT([no])]
 466 )
 467
 468 AC_MSG_CHECKING([whether a custom version is requested])
 469 AC_ARG_WITH(custom-version,
 470 AC_HELP_STRING([--with-custom-version=NAME],
 471                [Custom version branding.]),
 472                [BRANDING_VERSION=$withval
 473                 AC_MSG_RESULT([yes])],
 474                [BRANDING_VERSION=$PACKAGE_VERSION
 475                 AC_MSG_RESULT([no])]
 476 )
 477
 478 AC_DEFINE_UNQUOTED(BRANDING_NAME, ["$BRANDING_NAME"], [Custom branding name.])
 479 AC_DEFINE_UNQUOTED(BRANDING_VERSION, ["$BRANDING_VERSION"], [Custom branding name.])
 480
 481 if test "x$BRANDING_NAME" != "x$PACKAGE_NAME"; then
 482         AC_DEFINE(CUSTOM_BRANDING, 1, [Define if custom branding is enabled.])
 483 fi
 484
 485 dnl **********************************************************************
 486 dnl Enable oper chghost
 487 dnl **********************************************************************
 488
 489 AC_ARG_ENABLE(oper-chghost,
 490 AC_HELP_STRING([--enable-oper-chghost],[Enable opers to use the CHGHOST command]),
 491 [operchghost=$enableval],[operchghost=no])
 492
 493 if test "$operchghost" = yes; then
 494         AC_DEFINE(ENABLE_OPER_CHGHOST, 1, [Define this to enable opers to use the CHGHOST command.])
 495 fi
 496
 497 dnl Debug-related options
 498 dnl =====================
 499
 500 AC_ARG_ENABLE(assert,
 501 AC_HELP_STRING([--enable-assert],[Enable assert(). Choose between soft(warnings) and hard(aborts the daemon)]),
 502 [assert=$enableval], [assert=no])
 503
 504 if test "$assert" = no; then
 505         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 506 elif test "$assert" = soft; then
 507         AC_DEFINE(SOFT_ASSERT, 1, [Define this to enable soft asserts.])
 508         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 509 elif test "$assert" = yes; then
 510         assert = "hard";
 511 fi
 512
 513 AC_MSG_CHECKING(if you want to do a profile build)
 514 AC_ARG_ENABLE(profile,
 515 AC_HELP_STRING([--enable-profile],[Enable profiling]),
 516 [profile=$enableval], [profile=no])
 517
 518 if test "$profile" = yes; then
 519         if test "$ac_cv_c_compiler_gnu" = yes; then
 520                 IRC_CFLAGS="$IRC_CFLAGS -pg"
 521                 AC_MSG_RESULT([yes, adding -pg])
 522                 AC_DEFINE(CHARYBDIS_PROFILE, 1, [Define this if you are profiling.])
 523         else
 524                 AC_MSG_RESULT([no, profile builds only work with gcc])
 525         fi
 526 else
 527         AC_MSG_RESULT(no)
 528 fi
 529
 530 AC_DEFINE([NICKNAMEHISTORYLENGTH], 15000, [Size of the WHOWAS array.])
 531 AC_DEFINE([CHANNEL_HEAP_SIZE], 8192, [Size of the channel heap.])
 532 AC_DEFINE([BAN_HEAP_SIZE], 4096, [Size of the ban heap.])
 533 AC_DEFINE([CLIENT_HEAP_SIZE], 8192, [Size of the client heap.])
 534 AC_DEFINE([LCLIENT_HEAP_SIZE], 1024, [Size of the local client heap.])
 535 AC_DEFINE([PCLIENT_HEAP_SIZE], 256, [Size of the pre-client heap.])
 536 AC_DEFINE([USER_HEAP_SIZE], 8192, [Size of the user heap.])
 537 AC_DEFINE([DNODE_HEAP_SIZE], 8192, [Size of the dlink_node heap.])
 538 AC_DEFINE([TOPIC_HEAP_SIZE], 4096, [Size of the topic heap.])
 539 AC_DEFINE([LINEBUF_HEAP_SIZE], 2048, [Size of the linebuf heap.])
 540 AC_DEFINE([MEMBER_HEAP_SIZE], 32768, [Sizeof member heap.])
 541 AC_DEFINE([ND_HEAP_SIZE], 512, [Size of the nick delay heap.])
 542 AC_DEFINE([CONFITEM_HEAP_SIZE], 256, [Size of the confitem heap.])
 543 AC_DEFINE([MONITOR_HEAP_SIZE], 1024, [Size of the monitor heap.])
 544 AC_DEFINE([FD_HEAP_SIZE], 1024, [Size of fd heap.])
 545 AC_DEFINE([AWAY_HEAP_SIZE], 512, [Size of away heap.])
 546
 547 AC_ARG_WITH(nicklen,
 548 AC_HELP_STRING([--with-nicklen=LENGTH],[Set the upper-bound nick length to LENGTH (default 31, max 50)]),
 549 [
 550   if ! expr "$withval" + 0 >/dev/null 2>&1; then
 551         AC_ERROR([NICKLEN must be a numeric value])
 552   fi
 553   if test $withval -gt 50; then
 554         NICKLEN=50
 555         AC_MSG_WARN([NICKLEN has a hard limit of 50. Setting NICKLEN=50])
 556   elif test $withval -lt 9; then
 557         NICKLEN=9
 558         AC_MSG_WARN([NICKLEN has a lower limit of 9. Setting NICKLEN=9])
 559   else
 560         NICKLEN="$withval"
 561   fi
 562 ], [NICKLEN=31])
 563
 564 AC_ARG_WITH(topiclen,
 565 AC_HELP_STRING([--with-topiclen=NUMBER],[Set the max topic length to NUMBER (default 390, max 390)]),
 566 [
 567  if test $withval -gt 390; then
 568         TOPICLEN=390
 569         AC_MSG_WARN([TOPICLEN has a hard limit of 390. Setting TOPICLEN=390])
 570  else
 571         TOPICLEN=$withval
 572  fi
 573 ], [TOPICLEN=390])
 574
 575 AC_DEFINE_UNQUOTED(TOPICLEN, ${TOPICLEN}, [Maximum topic length (<=390)])
 576 AC_DEFINE_UNQUOTED(NICKLEN, (${NICKLEN}+1), [Nickname length])
 577
 578 # rpath, for finding librb.so at run time
 579 hold_ldflags=$LDFLAGS
 580 AC_MSG_CHECKING(for the ld -rpath flag)
 581 LDFLAGS="${LDFLAGS} -Wl,-rpath=${libdir}"
 582 AC_LINK_IFELSE([AC_LANG_PROGRAM([],[int i;])], found=yes, found=no)
 583 LDFLAGS=$hold_ldflags
 584 AC_MSG_RESULT($found)
 585 if test "$found" = yes; then
 586         LDFLAGS="${LDFLAGS} -Wl,-rpath=\${libdir}"
 587 fi
 588
 589 # This must be down here, or it will mess up checks like the ones
 590 # for -Wl,-export-dynamic
 591 # -- jilles
 592 CWARNS=""
 593 AC_ARG_ENABLE(warnings,
 594 AC_HELP_STRING([--enable-warnings],[Enable all sorts of warnings for debugging.]),
 595 [
 596 IRC_CFLAGS="$IRC_CFLAGS -O0"
 597 CFLAGS="$IRC_CFLAGS"
 598
 599 CHARYBDIS_C_GCC_TRY_FLAGS([-Wall], charybdis_cv_c_gcc_w_all)
 600 CHARYBDIS_C_GCC_TRY_FLAGS([-Wpointer-arith], charybdis_cv_c_gcc_w_pointer_arith)
 601 CHARYBDIS_C_GCC_TRY_FLAGS([-Wimplicit -Wnested-externs], charybdis_cv_c_gcc_w_implicit)
 602 CHARYBDIS_C_GCC_TRY_FLAGS([-Wcast-align], charybdis_cv_c_gcc_w_cast_align)
 603 CHARYBDIS_C_GCC_TRY_FLAGS([-Wcast-qual], charybdis_cv_c_gcc_w_cast_qual)
 604 CHARYBDIS_C_GCC_TRY_FLAGS([-Wwrite-strings], charybdis_cv_c_gcc_w_write_strings)
 605 CHARYBDIS_C_GCC_TRY_FLAGS([-Werror-implicit-function-declaration], charybdis_cv_c_gcc_w_error_implicit_function_declaration)
 606 CHARYBDIS_C_GCC_TRY_FLAGS([-Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations], charybdis_cv_c_gcc_prototypes)
 607 CHARYBDIS_C_GCC_TRY_FLAGS([-Wparentheses], charybdis_cv_c_gcc_parentheses)
 608 CHARYBDIS_C_GCC_TRY_FLAGS([-W -Wno-unused], charybdis_cv_c_gcc_w)
 609 CHARYBDIS_C_GCC_TRY_FLAGS([-Wextra], charybdis_cv_c_gcc_w_extra)
 610 CHARYBDIS_C_GCC_TRY_FLAGS([-Wshadow], charybdis_cv_c_gcc_w_shadow)
 611 CHARYBDIS_C_GCC_TRY_FLAGS([-Wmissing-noreturn], charybdis_cv_c_gcc_w_missing_noreturn)
 612 CHARYBDIS_C_GCC_TRY_FLAGS([-Wundef], charybdis_cv_c_gcc_w_undef)
 613 CHARYBDIS_C_GCC_TRY_FLAGS([-Wpacked], charybdis_cv_c_gcc_w_packed)
 614 CHARYBDIS_C_GCC_TRY_FLAGS([-Wnested-externs], charybdis_cv_c_gcc_w_nested_externs)
 615 CHARYBDIS_C_GCC_TRY_FLAGS([-Wunused-function -Wunused-label -Wunused-value -Wunused-variable], charybdis_cv_c_gcc_w_unused)
 616 CHARYBDIS_C_GCC_TRY_FLAGS([-Wredundant-decls], charybdis_cv_c_gcc_w_redundant_decls)
 617 CHARYBDIS_C_GCC_TRY_FLAGS([-Wfloat-equal], charybdis_cv_c_gcc_w_float_equal)
 618 CHARYBDIS_C_GCC_TRY_FLAGS([-Wformat -Wformat-y2k -Wno-format-security], charybdis_cv_c_gcc_w_format)
 619
 620 IRC_CFLAGS="$CFLAGS"
 621 ],[])
 622
 623 IRC_CFLAGS="$IRC_CFLAGS $CWARNS"
 624
 625 AC_SUBST(MODULES_LIBS)
 626 AC_SUBST(MOD_TARGET)
 627
 628 AC_SUBST(SSL_SRCS_ENABLE)
 629 AC_SUBST(SSL_INCLUDES)
 630 AC_SUBST(SSL_LIBS)
 631
 632 AC_SUBST(LDFLAGS)
 633 AC_SUBST(PICFLAGS)
 634 AC_SUBST(IRC_CFLAGS)
 635 AC_SUBST(SEDOBJ)
 636
 637
 638 if test "$prefix" = "NONE"; then
 639         AC_DEFINE_UNQUOTED(IRCD_PREFIX, "$ac_default_prefix", [Prefix where the ircd is installed.])
 640
 641 else
 642
 643 dnl Don't get bitten by Cygwin's stupidity if the user specified
 644 dnl a custom prefix with a trailing slash
 645
 646         prefix=`echo $prefix | sed 's/\/$//'`
 647         AC_DEFINE_UNQUOTED(IRCD_PREFIX, "$prefix", [Prefix where the ircd is installed.])
 648
 649 fi
 650
 651 AC_CONFIG_FILES(                        \
 652         Makefile                        \
 653         authd/Makefile                  \
 654         bandb/Makefile                  \
 655         ssld/Makefile                   \
 656         wsockd/Makefile                 \
 657         extensions/Makefile             \
 658         ircd/Makefile                   \
 659         modules/Makefile                \
 660         tests/Makefile                  \
 661         tools/Makefile                  \
 662         tools/genssl                    \
 663         doc/Makefile                    \
 664         help/Makefile                   \
 665 )
 666 AC_CONFIG_COMMANDS([tools/genssl_chmod], [chmod 755 tools/genssl])
 667
 668 AC_OUTPUT
 669
 670 if test "$cf_openssl_version_ok" = yes; then
 671         openssl="yes"
 672 else
 673         openssl="no"
 674 fi
 675
 676 echo "
 677 Configuration of ${BRANDING_NAME}-${BRANDING_VERSION}:
 678         Install directory  : $prefix
 679
 680         Ziplinks           : $zlib
 681         OpenSSL            : $openssl
 682
 683         Nickname length    : $NICKLEN
 684         Topic length       : $TOPICLEN
 685
 686 Use (g)make to compile $BRANDING_NAME, then (g)make install to install it.
 687 "