CMakeLists.txt

   1 #
   2 # Copyright (C) 2003-2022 Sébastien Helleu <flashcode@flashtux.org>
   3 # Copyright (C) 2007-2008 Julien Louis <ptitlouis@sysif.net>
   4 # Copyright (C) 2008-2009 Emmanuel Bouthenot <kolter@openics.org>
   5 #
   6 # This file is part of WeeChat, the extensible chat client.
   7 #
   8 # WeeChat is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # WeeChat is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with WeeChat.  If not, see <https://www.gnu.org/licenses/>.
  20 #
  21
  22 cmake_minimum_required(VERSION 3.0)
  23
  24 project(weechat C)
  25
  26 # CMake options
  27 set(CMAKE_VERBOSE_MAKEFILE OFF)
  28 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
  29 set(CMAKE_SKIP_RPATH ON)
  30 set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsigned-char -fms-extensions -Wall -Wextra -Werror-implicit-function-declaration")
  31 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsigned-char -fms-extensions -Wall -Wextra")
  32
  33 # version
  34 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/version.sh devel-major OUTPUT_VARIABLE VERSION_MAJOR)
  35 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/version.sh devel-minor OUTPUT_VARIABLE VERSION_MINOR)
  36 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/version.sh devel-patch OUTPUT_VARIABLE VERSION_PATCH)
  37 string(REGEX REPLACE "\n" "" VERSION_MAJOR "${VERSION_MAJOR}")
  38 string(REGEX REPLACE "\n" "" VERSION_MINOR "${VERSION_MINOR}")
  39 string(REGEX REPLACE "\n" "" VERSION_PATCH "${VERSION_PATCH}")
  40 if(VERSION_PATCH STREQUAL "")
  41   set(VERSION ${VERSION_MAJOR}.${VERSION_MINOR})
  42 else()
  43   set(VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH})
  44 endif()
  45
  46 # license
  47 set(LICENSE "GPL3")
  48
  49 # add definitions for version and license
  50 if(COMMAND cmake_policy)
  51   cmake_policy(SET CMP0005 NEW)
  52   add_definitions(-DWEECHAT_VERSION="${VERSION}" -DWEECHAT_LICENSE="${LICENSE}")
  53 else()
  54   add_definitions(-DWEECHAT_VERSION='"${VERSION}"' -DWEECHAT_LICENSE='"${LICENSE}"')
  55 endif()
  56
  57 # package string
  58 set(PKG_STRING "${PROJECT_NAME} ${VERSION}")
  59 string(REPLACE "\";\"" "\ " PKG_STRING ${PKG_STRING})
  60
  61 if(NOT DEFINED LIBDIR)
  62   set(LIBDIR ${CMAKE_INSTALL_PREFIX}/lib)
  63 endif()
  64
  65 if(NOT DEFINED WEECHAT_LIBDIR)
  66   set(WEECHAT_LIBDIR ${LIBDIR}/${PROJECT_NAME})
  67 endif()
  68
  69 if(NOT DEFINED DATAROOTDIR)
  70   set(DATAROOTDIR ${CMAKE_INSTALL_PREFIX}/share)
  71 endif()
  72
  73 if(NOT DEFINED WEECHAT_SHAREDIR)
  74   set(WEECHAT_SHAREDIR ${DATAROOTDIR}/weechat)
  75 endif()
  76
  77 if(NOT DEFINED MANDIR)
  78   set(MANDIR ${DATAROOTDIR}/man)
  79 endif()
  80
  81 if(NOT DEFINED LOCALEDIR)
  82   set(LOCALEDIR ${DATAROOTDIR}/locale)
  83 endif()
  84
  85 if(DEFINED INCLUDEDIR)
  86   set(INCLUDEDIR ${INCLUDEDIR}/${PROJECT_NAME})
  87 else()
  88   set(INCLUDEDIR ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
  89 endif()
  90
  91 option(ENABLE_NCURSES       "Compile the Ncurses interface"               ON)
  92 option(ENABLE_HEADLESS      "Compile the headless binary (required for tests)" ON)
  93 option(ENABLE_NLS           "Enable Native Language Support"              ON)
  94 option(ENABLE_LARGEFILE     "Enable Large File Support"                   ON)
  95 option(ENABLE_ALIAS         "Enable Alias plugin"                         ON)
  96 option(ENABLE_BUFLIST       "Enable Buflist plugin"                       ON)
  97 option(ENABLE_CHARSET       "Enable Charset plugin"                       ON)
  98 option(ENABLE_EXEC          "Enable Exec plugin"                          ON)
  99 option(ENABLE_FIFO          "Enable FIFO plugin"                          ON)
 100 option(ENABLE_FSET          "Enable Fast Set plugin"                      ON)
 101 option(ENABLE_IRC           "Enable IRC plugin"                           ON)
 102 option(ENABLE_LOGGER        "Enable Logger plugin"                        ON)
 103 option(ENABLE_RELAY         "Enable Relay plugin"                         ON)
 104 option(ENABLE_SCRIPT        "Enable Script plugin (script manager)"       ON)
 105 option(ENABLE_SCRIPTS       "Enable script plugins (perl, python, ...)"   ON)
 106 option(ENABLE_PERL          "Enable Perl scripting language"              ON)
 107 option(ENABLE_PYTHON        "Enable Python scripting language"            ON)
 108 option(ENABLE_PYTHON2       "Use Python 2 instead of Python 3"            OFF)
 109 option(ENABLE_RUBY          "Enable Ruby scripting language"              ON)
 110 option(ENABLE_LUA           "Enable Lua scripting language"               ON)
 111 option(ENABLE_TCL           "Enable Tcl scripting language"               ON)
 112 option(ENABLE_GUILE         "Enable Scheme (guile) scripting language"    ON)
 113 option(ENABLE_JAVASCRIPT    "Enable JavaScript scripting language"        OFF)
 114 option(ENABLE_PHP           "Enable PHP scripting language"               ON)
 115 option(ENABLE_SPELL         "Enable Spell checker plugin"                 ON)
 116 option(ENABLE_ENCHANT       "Enable Enchant lib for Spell checker plugin" OFF)
 117 option(ENABLE_TRIGGER       "Enable Trigger plugin"                       ON)
 118 option(ENABLE_TYPING        "Enable Typing plugin"                        ON)
 119 option(ENABLE_XFER          "Enable Xfer plugin"                          ON)
 120 option(ENABLE_MAN           "Enable build of man page"                    OFF)
 121 option(ENABLE_DOC           "Enable build of documentation"               OFF)
 122 option(ENABLE_TESTS         "Enable tests"                                OFF)
 123 option(ENABLE_CODE_COVERAGE "Enable code coverage"                        OFF)
 124
 125 # code coverage
 126 add_library(coverage_config INTERFACE)
 127 if(ENABLE_CODE_COVERAGE)
 128   target_compile_options(coverage_config INTERFACE -O0 -g --coverage)
 129   target_link_libraries(coverage_config INTERFACE --coverage)
 130 endif()
 131
 132 # headless mode is required for tests
 133 if(ENABLE_TESTS AND NOT ENABLE_HEADLESS)
 134   message(FATAL_ERROR "Headless mode is required for tests.")
 135 endif()
 136
 137 # option WEECHAT_HOME
 138 set(WEECHAT_HOME "${WEECHAT_HOME}" CACHE
 139   STRING "Force a single WeeChat home directory for config, logs, scripts, etc."
 140   FORCE)
 141 mark_as_advanced(CLEAR WEECHAT_HOME)
 142
 143 if(COMMAND cmake_policy)
 144   if(POLICY CMP0003)
 145     cmake_policy(SET CMP0003 NEW)
 146   endif()
 147   if(POLICY CMP0017)
 148     cmake_policy(SET CMP0017 NEW)
 149   endif()
 150 endif()
 151
 152 add_definitions(-DHAVE_CONFIG_H)
 153
 154 include(FindPkgConfig)
 155
 156 include(CheckIncludeFiles)
 157 include(CheckFunctionExists)
 158 include(CheckSymbolExists)
 159
 160 check_include_files("langinfo.h" HAVE_LANGINFO_CODESET)
 161 check_include_files("sys/resource.h" HAVE_SYS_RESOURCE_H)
 162
 163 check_function_exists(mallinfo HAVE_MALLINFO)
 164 check_function_exists(mallinfo2 HAVE_MALLINFO2)
 165
 166 check_symbol_exists("eat_newline_glitch" "term.h" HAVE_EAT_NEWLINE_GLITCH)
 167
 168 # Check for Large File Support
 169 if(ENABLE_LARGEFILE)
 170   add_definitions(-D_FILE_OFFSET_BITS=64 -D_LARGEFILE64_SOURCE -D_LARGEFILE_SOURCE -D_LARGE_FILES)
 171 endif()
 172
 173 # Check for Gettext
 174 if(ENABLE_NLS)
 175   find_package(Gettext)
 176   if(GETTEXT_FOUND)
 177     add_definitions(-DENABLE_NLS)
 178     find_package(Intl)
 179     if(Intl_FOUND)
 180       list(APPEND EXTRA_LIBS "${Intl_LIBRARIES}")
 181     endif()
 182   else()
 183     message(SEND_ERROR "Gettext not found")
 184   endif()
 185 endif()
 186
 187 # Check for libgcrypt
 188 find_package(GCRYPT REQUIRED)
 189 add_definitions(-DHAVE_GCRYPT)
 190 list(APPEND EXTRA_LIBS ${GCRYPT_LDFLAGS})
 191
 192 # Check for GnuTLS
 193 find_package(GnuTLS REQUIRED)
 194 string(REGEX REPLACE "/[^/]*$" "" GNUTLS_LIBRARY_PATH "${GNUTLS_LIBRARY}")
 195 include_directories(${GNUTLS_INCLUDE_PATH})
 196 set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${GNUTLS_LIBRARY_PATH}")
 197 list(APPEND EXTRA_LIBS gnutls)
 198
 199 # Check for zlib
 200 find_package(ZLIB REQUIRED)
 201
 202 # Check for zstd
 203 pkg_check_modules(LIBZSTD REQUIRED libzstd)
 204
 205 # Check for iconv
 206 find_package(Iconv)
 207 if(ICONV_FOUND)
 208   add_definitions(-DHAVE_ICONV)
 209 endif()
 210
 211 # Check for CURL
 212 find_package(CURL REQUIRED)
 213
 214 # weechat_gui_common MUST be the first lib in the list
 215 set(STATIC_LIBS weechat_gui_common)
 216
 217 find_library(DL_LIBRARY
 218   NAMES dl
 219   PATHS /lib /usr/lib /usr/libexec /usr/local/lib /usr/local/libexec
 220 )
 221 list(APPEND STATIC_LIBS weechat_plugins)
 222 if(DL_LIBRARY)
 223   string(REGEX REPLACE "/[^/]*$" "" DL_LIBRARY_PATH "${DL_LIBRARY}")
 224   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${DL_LIBRARY_PATH}")
 225   list(APPEND EXTRA_LIBS dl)
 226 endif()
 227
 228 add_subdirectory(icons)
 229
 230 if(ENABLE_NLS)
 231   add_subdirectory(po)
 232 endif()
 233
 234 add_subdirectory(src)
 235 add_subdirectory(doc)
 236
 237 if(ENABLE_TESTS)
 238   find_package(CppUTest)
 239   if(CPPUTEST_FOUND)
 240     enable_testing()
 241     add_subdirectory(tests)
 242   else()
 243     message(SEND_ERROR "CppUTest not found")
 244   endif()
 245 endif()
 246
 247 configure_file(config.h.cmake config.h @ONLY)
 248
 249 # set the git version in "config-git.h"
 250 add_custom_target(version_git ALL
 251   COMMAND "${CMAKE_CURRENT_SOURCE_DIR}/tools/git-version.sh" "${CMAKE_CURRENT_SOURCE_DIR}" "${VERSION}" "config-git.h"
 252   WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
 253 )
 254
 255 configure_file(
 256   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 257   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 258   IMMEDIATE @ONLY
 259 )
 260
 261 add_custom_target(uninstall
 262   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 263 )
 264
 265 add_custom_target(dist
 266   "${CMAKE_CURRENT_SOURCE_DIR}/tools/makedist.sh" "${VERSION}" "HEAD" "${CMAKE_CURRENT_BINARY_DIR}"
 267   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 268 )
 269
 270 # pkgconfig file
 271 set(PACKAGE "${PROJECT_NAME}")
 272 set(prefix "${CMAKE_INSTALL_PREFIX}")
 273 set(exec_prefix "\${prefix}")
 274 string(REPLACE "${CMAKE_INSTALL_PREFIX}" "\${prefix}" libdir "${LIBDIR}")
 275 set(includedir "\${prefix}/include")
 276 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/weechat.pc.in ${CMAKE_CURRENT_BINARY_DIR}/weechat.pc @ONLY)
 277 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/weechat.pc DESTINATION ${LIBDIR}/pkgconfig)
 278
 279 # cygport file (used to build Cygwin packages)
 280 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/weechat.cygport.in ${CMAKE_CURRENT_BINARY_DIR}/weechat-${VERSION}-1.cygport @ONLY)
 281
 282 # install some files (only on Cygwin)
 283 if(CYGWIN)
 284   install(FILES
 285     ${CMAKE_CURRENT_SOURCE_DIR}/AUTHORS.adoc
 286     ${CMAKE_CURRENT_SOURCE_DIR}/ChangeLog.adoc
 287     ${CMAKE_CURRENT_SOURCE_DIR}/Contributing.adoc
 288     ${CMAKE_CURRENT_SOURCE_DIR}/README.adoc
 289     ${CMAKE_CURRENT_SOURCE_DIR}/ReleaseNotes.adoc
 290     DESTINATION ${DATAROOTDIR}/doc/${PROJECT_NAME}
 291   )
 292 endif()
 293
 294 # desktop file
 295 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/weechat.desktop DESTINATION ${DATAROOTDIR}/applications)
 296
 297 # packages
 298 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Fast, light and extensible chat client")
 299 set(CPACK_PACKAGE_VENDOR "Sébastien Helleu")
 300 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.adoc")
 301 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 302 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 303 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 304 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 305
 306 # binary package
 307 set(CPACK_GENERATOR "STGZ;TGZ;TBZ2")
 308 set(CPACK_PACKAGE_FILE_NAME weechat-binary-${VERSION})
 309
 310 # source package
 311 set(CPACK_SOURCE_GENERATOR "TGZ;TBZ2")
 312 set(CPACK_SOURCE_PACKAGE_FILE_NAME weechat-${VERSION})
 313 set(CPACK_SOURCE_IGNORE_FILES
 314   "/\\\\.git" "/build/" "/m4/"
 315   "/autom4te\\\\.cache/" "/ABOUT-NLS$" "/config\\\\.guess$" "/config\\\\.h$"
 316   "/config\\\\.h.in$" "/config\\\\.log$" "/config\\\\.rpath$"
 317   "/config\\\\.status$" "/config\\\\.sub$" "/configure$" "/depcomp$"
 318   "/install-sh$" "/missing$" "/intl/" "/libtool$" "/\\\\.libs/"
 319   "/ltmain\\\\.sh$" "/\\\\.deps/" "/html/" "/html1/" "/Makefile$"
 320   "/Makefile\\\\.in$" "stamp" "/po/.*\\\\.header$" "\\\\.gmo$" "~$" "\\\\.o$"
 321   "\\\\.lo$" "\\\\.a$" "\\\\.la$" "\\\\.lai$" "\\\\.Plo$" "/weechat$"
 322 )
 323
 324 include(CPack)