CMakeLists.txt

   1 #
   2 # Copyright (C) 2003-2020 Sébastien Helleu <flashcode@flashtux.org>
   3 # Copyright (C) 2007-2008 Julien Louis <ptitlouis@sysif.net>
   4 # Copyright (C) 2008-2009 Emmanuel Bouthenot <kolter@openics.org>
   5 #
   6 # This file is part of WeeChat, the extensible chat client.
   7 #
   8 # WeeChat is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # WeeChat is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with WeeChat.  If not, see <https://www.gnu.org/licenses/>.
  20 #
  21
  22 cmake_minimum_required(VERSION 3.0)
  23
  24 project(weechat C)
  25
  26 # CMake options
  27 set(CMAKE_VERBOSE_MAKEFILE OFF)
  28 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
  29 set(CMAKE_SKIP_RPATH ON)
  30 set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsigned-char -Wall -Wextra -Werror-implicit-function-declaration")
  31 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsigned-char -Wall -Wextra")
  32
  33 # version
  34 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/version.sh devel-major OUTPUT_VARIABLE VERSION_MAJOR)
  35 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/version.sh devel-minor OUTPUT_VARIABLE VERSION_MINOR)
  36 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/version.sh devel-patch OUTPUT_VARIABLE VERSION_PATCH)
  37 string(REGEX REPLACE "\n" "" VERSION_MAJOR "${VERSION_MAJOR}")
  38 string(REGEX REPLACE "\n" "" VERSION_MINOR "${VERSION_MINOR}")
  39 string(REGEX REPLACE "\n" "" VERSION_PATCH "${VERSION_PATCH}")
  40 if(VERSION_PATCH STREQUAL "")
  41   set(VERSION ${VERSION_MAJOR}.${VERSION_MINOR})
  42 else()
  43   set(VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH})
  44 endif()
  45
  46 # license
  47 set(LICENSE "GPL3")
  48
  49 # add definitions for version and license
  50 if(COMMAND cmake_policy)
  51   cmake_policy(SET CMP0005 NEW)
  52   add_definitions(-DWEECHAT_VERSION="${VERSION}" -DWEECHAT_LICENSE="${LICENSE}")
  53 else()
  54   add_definitions(-DWEECHAT_VERSION='"${VERSION}"' -DWEECHAT_LICENSE='"${LICENSE}"')
  55 endif()
  56
  57 # package string
  58 set(PKG_STRING "${PROJECT_NAME} ${VERSION}")
  59 string(REPLACE "\";\"" "\ " PKG_STRING ${PKG_STRING})
  60
  61 if(NOT DEFINED LIBDIR)
  62   set(LIBDIR ${CMAKE_INSTALL_PREFIX}/lib)
  63 endif()
  64
  65 if(NOT DEFINED WEECHAT_LIBDIR)
  66   set(WEECHAT_LIBDIR ${LIBDIR}/${PROJECT_NAME})
  67 endif()
  68
  69 if(NOT DEFINED DATAROOTDIR)
  70   set(DATAROOTDIR ${CMAKE_INSTALL_PREFIX}/share)
  71 endif()
  72
  73 if(NOT DEFINED WEECHAT_SHAREDIR)
  74   set(WEECHAT_SHAREDIR ${DATAROOTDIR}/weechat)
  75 endif()
  76
  77 if(NOT DEFINED MANDIR)
  78   set(MANDIR ${DATAROOTDIR}/man)
  79 endif()
  80
  81 if(NOT DEFINED LOCALEDIR)
  82   set(LOCALEDIR ${DATAROOTDIR}/locale)
  83 endif()
  84
  85 if(DEFINED INCLUDEDIR)
  86   set(INCLUDEDIR ${INCLUDEDIR}/${PROJECT_NAME})
  87 else()
  88   set(INCLUDEDIR ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
  89 endif()
  90
  91 option(ENABLE_NCURSES       "Compile the Ncurses interface"               ON)
  92 option(ENABLE_HEADLESS      "Compile the headless binary (required for tests)" ON)
  93 option(ENABLE_NLS           "Enable Native Language Support"              ON)
  94 option(ENABLE_LARGEFILE     "Enable Large File Support"                   ON)
  95 option(ENABLE_ALIAS         "Enable Alias plugin"                         ON)
  96 option(ENABLE_BUFLIST       "Enable Buflist plugin"                       ON)
  97 option(ENABLE_CHARSET       "Enable Charset plugin"                       ON)
  98 option(ENABLE_EXEC          "Enable Exec plugin"                          ON)
  99 option(ENABLE_FIFO          "Enable FIFO plugin"                          ON)
 100 option(ENABLE_FSET          "Enable Fast Set plugin"                      ON)
 101 option(ENABLE_IRC           "Enable IRC plugin"                           ON)
 102 option(ENABLE_LOGGER        "Enable Logger plugin"                        ON)
 103 option(ENABLE_RELAY         "Enable Relay plugin"                         ON)
 104 option(ENABLE_SCRIPT        "Enable Script plugin (script manager)"       ON)
 105 option(ENABLE_SCRIPTS       "Enable script plugins (perl, python, ...)"   ON)
 106 option(ENABLE_PERL          "Enable Perl scripting language"              ON)
 107 option(ENABLE_PYTHON        "Enable Python scripting language"            ON)
 108 option(ENABLE_PYTHON2       "Use Python 2 instead of Python 3"            OFF)
 109 option(ENABLE_RUBY          "Enable Ruby scripting language"              ON)
 110 option(ENABLE_LUA           "Enable Lua scripting language"               ON)
 111 option(ENABLE_TCL           "Enable Tcl scripting language"               ON)
 112 option(ENABLE_GUILE         "Enable Scheme (guile) scripting language"    ON)
 113 option(ENABLE_JAVASCRIPT    "Enable JavaScript scripting language"        OFF)
 114 option(ENABLE_PHP           "Enable PHP scripting language"               ON)
 115 option(ENABLE_SPELL         "Enable Spell checker plugin"                 ON)
 116 option(ENABLE_ENCHANT       "Enable Enchant lib for Spell checker plugin" OFF)
 117 option(ENABLE_TRIGGER       "Enable Trigger plugin"                       ON)
 118 option(ENABLE_XFER          "Enable Xfer plugin"                          ON)
 119 option(ENABLE_MAN           "Enable build of man page"                    OFF)
 120 option(ENABLE_DOC           "Enable build of documentation"               OFF)
 121 option(ENABLE_TESTS         "Enable tests"                                OFF)
 122 option(ENABLE_CODE_COVERAGE "Enable code coverage"                        OFF)
 123
 124 # code coverage
 125 add_library(coverage_config INTERFACE)
 126 if(ENABLE_CODE_COVERAGE)
 127   target_compile_options(coverage_config INTERFACE -O0 -g --coverage)
 128   target_link_libraries(coverage_config INTERFACE --coverage)
 129 endif()
 130
 131 # headless mode is required for tests
 132 if(ENABLE_TESTS AND NOT ENABLE_HEADLESS)
 133   message(FATAL_ERROR "Headless mode is required for tests.")
 134 endif()
 135
 136 # option WEECHAT_HOME
 137 if(NOT DEFINED WEECHAT_HOME OR "${WEECHAT_HOME}" STREQUAL "")
 138   set(WEECHAT_HOME "~/.weechat")
 139 endif()
 140 set(WEECHAT_HOME "${WEECHAT_HOME}" CACHE
 141   STRING "WeeChat home directory for config, logs, scripts.. (default is \"~/.weechat\")"
 142   FORCE)
 143 mark_as_advanced(CLEAR WEECHAT_HOME)
 144
 145 # option CA_FILE
 146 if(NOT DEFINED CA_FILE OR "${CA_FILE}" STREQUAL "")
 147   set(CA_FILE "/etc/ssl/certs/ca-certificates.crt")
 148 endif()
 149 set(CA_FILE "${CA_FILE}" CACHE
 150   STRING "File containing the certificate authorities (default is \"/etc/ssl/certs/ca-certificates.crt\"). This is the default value of option \"weechat.network.gnutls_ca_file\"."
 151   FORCE)
 152 mark_as_advanced(CLEAR CA_FILE)
 153
 154 if(COMMAND cmake_policy)
 155   if(POLICY CMP0003)
 156     cmake_policy(SET CMP0003 NEW)
 157   endif()
 158   if(POLICY CMP0017)
 159     cmake_policy(SET CMP0017 NEW)
 160   endif()
 161 endif()
 162
 163 add_definitions(-DHAVE_CONFIG_H)
 164
 165 include(CheckIncludeFiles)
 166 include(CheckFunctionExists)
 167 include(CheckSymbolExists)
 168
 169 check_include_files("langinfo.h" HAVE_LANGINFO_CODESET)
 170 check_include_files("sys/resource.h" HAVE_SYS_RESOURCE_H)
 171
 172 check_function_exists(mallinfo HAVE_MALLINFO)
 173
 174 check_symbol_exists("eat_newline_glitch" "term.h" HAVE_EAT_NEWLINE_GLITCH)
 175
 176 # Check for Large File Support
 177 if(ENABLE_LARGEFILE)
 178   add_definitions(-D_FILE_OFFSET_BITS=64 -D_LARGEFILE64_SOURCE -D_LARGEFILE_SOURCE -D_LARGE_FILES)
 179 endif()
 180
 181 # Check for Gettext
 182 if(ENABLE_NLS)
 183   find_package(Gettext)
 184   if(GETTEXT_FOUND)
 185     add_definitions(-DENABLE_NLS)
 186     find_package(Intl)
 187     if(Intl_FOUND)
 188       list(APPEND EXTRA_LIBS "${Intl_LIBRARIES}")
 189     endif()
 190   else()
 191     message(SEND_ERROR "Gettext not found")
 192   endif()
 193 endif()
 194
 195 # Check for libgcrypt
 196 find_package(GCRYPT REQUIRED)
 197 add_definitions(-DHAVE_GCRYPT)
 198 list(APPEND EXTRA_LIBS ${GCRYPT_LDFLAGS})
 199
 200 # Check for GnuTLS
 201 find_package(GnuTLS REQUIRED)
 202 string(REGEX REPLACE "/[^/]*$" "" GNUTLS_LIBRARY_PATH "${GNUTLS_LIBRARY}")
 203 include_directories(${GNUTLS_INCLUDE_PATH})
 204 set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${GNUTLS_LIBRARY_PATH}")
 205 list(APPEND EXTRA_LIBS gnutls)
 206
 207 # Check for zlib
 208 find_package(ZLIB REQUIRED)
 209 add_definitions(-DHAVE_ZLIB)
 210
 211 # Check for iconv
 212 find_package(Iconv)
 213 if(ICONV_FOUND)
 214   add_definitions(-DHAVE_ICONV)
 215 endif()
 216
 217 # Check for CURL
 218 find_package(CURL REQUIRED)
 219
 220 # weechat_gui_common MUST be the first lib in the list
 221 set(STATIC_LIBS weechat_gui_common)
 222
 223 find_library(DL_LIBRARY
 224   NAMES dl
 225   PATHS /lib /usr/lib /usr/libexec /usr/local/lib /usr/local/libexec
 226 )
 227 list(APPEND STATIC_LIBS weechat_plugins)
 228 if(DL_LIBRARY)
 229   string(REGEX REPLACE "/[^/]*$" "" DL_LIBRARY_PATH "${DL_LIBRARY}")
 230   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${DL_LIBRARY_PATH}")
 231   list(APPEND EXTRA_LIBS dl)
 232 endif()
 233
 234 add_subdirectory(icons)
 235
 236 if(ENABLE_NLS)
 237   add_subdirectory(po)
 238 endif()
 239
 240 add_subdirectory(src)
 241 add_subdirectory(doc)
 242
 243 if(ENABLE_TESTS)
 244   find_package(CppUTest)
 245   if(CPPUTEST_FOUND)
 246     enable_testing()
 247     add_subdirectory(tests)
 248   else()
 249     message(SEND_ERROR "CppUTest not found")
 250   endif()
 251 endif()
 252
 253 configure_file(config.h.cmake config.h @ONLY)
 254
 255 # set the git version in "config-git.h"
 256 add_custom_target(version_git ALL
 257   COMMAND "${CMAKE_CURRENT_SOURCE_DIR}/tools/git-version.sh" "${CMAKE_CURRENT_SOURCE_DIR}" "${VERSION}" "config-git.h"
 258   WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
 259 )
 260
 261 configure_file(
 262   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 263   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 264   IMMEDIATE @ONLY
 265 )
 266
 267 add_custom_target(uninstall
 268   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 269 )
 270
 271 add_custom_target(dist
 272   "${CMAKE_CURRENT_SOURCE_DIR}/tools/makedist.sh" "${VERSION}" "HEAD" "${CMAKE_CURRENT_BINARY_DIR}"
 273   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 274 )
 275
 276 # pkgconfig file
 277 set(PACKAGE "${PROJECT_NAME}")
 278 set(prefix "${CMAKE_INSTALL_PREFIX}")
 279 set(exec_prefix "\${prefix}")
 280 string(REPLACE "${CMAKE_INSTALL_PREFIX}" "\${prefix}" libdir "${LIBDIR}")
 281 set(includedir "\${prefix}/include")
 282 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/weechat.pc.in ${CMAKE_CURRENT_BINARY_DIR}/weechat.pc @ONLY)
 283 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/weechat.pc DESTINATION ${LIBDIR}/pkgconfig)
 284
 285 # cygport file (used to build Cygwin packages)
 286 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/weechat.cygport.in ${CMAKE_CURRENT_BINARY_DIR}/weechat-${VERSION}-1.cygport @ONLY)
 287
 288 # install some files (only on Cygwin)
 289 if(CYGWIN)
 290   install(FILES
 291     ${CMAKE_CURRENT_SOURCE_DIR}/AUTHORS.adoc
 292     ${CMAKE_CURRENT_SOURCE_DIR}/ChangeLog.adoc
 293     ${CMAKE_CURRENT_SOURCE_DIR}/Contributing.adoc
 294     ${CMAKE_CURRENT_SOURCE_DIR}/README.adoc
 295     ${CMAKE_CURRENT_SOURCE_DIR}/ReleaseNotes.adoc
 296     DESTINATION ${DATAROOTDIR}/doc/${PROJECT_NAME}
 297   )
 298 endif()
 299
 300 # desktop file
 301 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/weechat.desktop DESTINATION ${DATAROOTDIR}/applications)
 302
 303 # packages
 304 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Fast, light and extensible chat client")
 305 set(CPACK_PACKAGE_VENDOR "Sébastien Helleu")
 306 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.adoc")
 307 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 308 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 309 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 310 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 311
 312 # binary package
 313 set(CPACK_GENERATOR "STGZ;TGZ;TBZ2")
 314 set(CPACK_PACKAGE_FILE_NAME weechat-binary-${VERSION})
 315
 316 # source package
 317 set(CPACK_SOURCE_GENERATOR "TGZ;TBZ2")
 318 set(CPACK_SOURCE_PACKAGE_FILE_NAME weechat-${VERSION})
 319 set(CPACK_SOURCE_IGNORE_FILES
 320   "/\\\\.git" "/build/" "/m4/"
 321   "/autom4te\\\\.cache/" "/ABOUT-NLS$" "/config\\\\.guess$" "/config\\\\.h$"
 322   "/config\\\\.h.in$" "/config\\\\.log$" "/config\\\\.rpath$"
 323   "/config\\\\.status$" "/config\\\\.sub$" "/configure$" "/depcomp$"
 324   "/install-sh$" "/missing$" "/intl/" "/libtool$" "/\\\\.libs/"
 325   "/ltmain\\\\.sh$" "/\\\\.deps/" "/html/" "/html1/" "/Makefile$"
 326   "/Makefile\\\\.in$" "stamp" "/po/.*\\\\.header$" "\\\\.gmo$" "~$" "\\\\.o$"
 327   "\\\\.lo$" "\\\\.a$" "\\\\.la$" "\\\\.lai$" "\\\\.Plo$" "/weechat$"
 328 )
 329
 330 include(CPack)