aclocal.m4

   1 # $Id: aclocal.m4 3321 2007-03-30 23:32:43Z jilles $ - aclocal.m4 - Autoconf fun...
   2 AC_DEFUN([AC_DEFINE_DIR], [
   3   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
   4   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
   5   last_ac_define_dir=`eval echo [$]$2`
   6   ac_define_dir=`eval echo [$]last_ac_define_dir`
   7   ac_define_dir_counter=0
   8   while test "x[$]last_ac_define_dir" != "x[$]ac_define_dir"; do
   9     last_ac_define_dir="[$]ac_define_dir"
  10     ac_define_dir=`eval echo [$]last_ac_define_dir`
  11     AS_VAR_ARITH([ac_define_dir_counter], [$ac_define_dir_counter + 1])
  12     AS_VAR_IF([ac_define_dir_counter], [128],
  13         [AC_MSG_ERROR([detected recusive directory expansion when expanding $1=[$]$2: [$]ac_define_dir])
  14         break])
  15   done
  16   $1="$ac_define_dir"
  17   AC_SUBST($1)
  18   ifelse($3, ,
  19     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
  20     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
  21 ])
  22
  23 AC_DEFUN([AC_SUBST_DIR], [
  24         ifelse($2,,,$1="[$]$2")
  25         $1=`(
  26             test "x$prefix" = xNONE && prefix="$ac_default_prefix"
  27             test "x$exec_prefix" = xNONE && exec_prefix="${prefix}"
  28             eval echo \""[$]$1"\"
  29         )`
  30         AC_SUBST($1)
  31 ])
  32
  33 dnl CHARYBDIS_C_GCC_TRY_FLAGS(<warnings>,<cachevar>)
  34 AC_DEFUN([CHARYBDIS_C_GCC_TRY_FLAGS],[
  35  AC_MSG_CHECKING([GCC flag(s) $1])
  36  if test "${GCC-no}" = yes
  37  then
  38   AC_CACHE_VAL($2,[
  39    oldcflags="${CFLAGS-}"
  40    CFLAGS="${CFLAGS-} ${CWARNS} $1 -Werror"
  41    AC_TRY_COMPILE([
  42 #include <string.h>
  43 #include <stdio.h>
  44 int main(void);
  45 ],[
  46     (void)strcmp("a","b"); fprintf(stdout,"test ok\n");
  47 ], [$2=yes], [$2=no])
  48    CFLAGS="${oldcflags}"])
  49   if test "x$$2" = xyes; then
  50    CWARNS="${CWARNS}$1 "
  51    AC_MSG_RESULT(ok)
  52   else
  53    $2=''
  54    AC_MSG_RESULT(no)
  55   fi
  56  else
  57   AC_MSG_RESULT(no, not using GCC)
  58  fi
  59 ])