libratbox/configure.ac

   1 dnl $Id: configure.ac 26168 2008-10-26 20:58:40Z androsyn $
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl TODO: clean up all the OpenSSL and shared module checking stuff;
   5 dnl the most major changes have already been made and it looks like
   6 dnl said functions need to be just about as complex as they already are.
   7
   8 AC_PREREQ(2.61)
   9 AUTOMAKE_OPTIONS = 1.10
  10 dnl Sneaky way to get an Id tag into the configure script
  11 AC_COPYRIGHT([$Id: configure.ac 26168 2008-10-26 20:58:40Z androsyn $])
  12 AC_INIT([libratbox],[devel])
  13 AM_INIT_AUTOMAKE(AC_PACKAGE_TARNAME, AC_PACKAGE_VERSION, -)
  14
  15 AM_CONFIG_HEADER(include/libratbox_config.h)
  16
  17 AC_PREFIX_DEFAULT(/usr/local/libratbox)
  18 AC_GNU_SOURCE
  19
  20 dnl Checks for programs.
  21 AC_PROG_CC_C99
  22
  23 if test x"$ac_cv_prog_cc_c99" = "xno"; then
  24         AC_ERROR([ircd-ratbox requires a C99 capable compiler])
  25 fi
  26
  27
  28 AC_PROG_INSTALL
  29 AC_PROG_EGREP
  30 AC_PROG_SED
  31
  32 F77=no
  33 CXX=no
  34 GCJ=no
  35
  36 AM_DISABLE_STATIC
  37 AM_ENABLE_SHARED
  38 AM_MAINTAINER_MODE
  39
  40 AC_ISC_POSIX
  41 AC_C_INLINE
  42 AC_C_CONST
  43 AC_PROG_MAKE_SET
  44 AC_PROG_INSTALL
  45 AC_PATH_PROG(AUTOMAKE, automake)
  46 AC_PATH_PROG(ACLOCAL, aclocal)
  47 AC_PATH_PROG(AUTOHEADER, autoheader)
  48 AC_PATH_PROG(AS, as)
  49 AC_PATH_PROG(RM, rm)
  50 AC_PATH_PROG(CP, cp)
  51 AC_PATH_PROG(MV, mv)
  52 AC_PATH_PROG(LN, ln)
  53 AC_PATH_PROG(TOUCH, touch)
  54 AC_LANG(C)
  55
  56 AC_PROG_LIBTOOL
  57
  58 LIBTOOL="$LIBTOOL --silent"
  59
  60 case "$host_os" in
  61 *cygwin*)
  62      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
  63      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  64      ;;
  65 *mingw*)
  66      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
  67      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  68      AC_CHECK_HEADER(windows.h, , [AC_MSG_ERROR([** MinGW and no windows.h.  I give up.])])
  69      AC_CHECK_HEADER(winsock2.h, , [AC_MSG_ERROR([** MinGW and no winsock2.h.  I give up.])])
  70      AC_DEFINE_UNQUOTED(HAVE_WINSOCK2_H, 1, [Have WINSOCK2_H])
  71      AC_DEFINE_UNQUOTED(HAVE_WINSOCK_H, 1, [Have WINSOCK_H])
  72      LIBS="$LIBS -lws2_32 -liphlpapi"
  73      is_mingw="yes"
  74      ;;
  75 *interix*)
  76      CPPFLAGS="$CFLAGS -D_ALL_SOURCE -D_XOPEN_SOURCE=500"
  77      ;;
  78 *solaris*|*sunos*)
  79      CPPFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_XPG4_2 -D__EXTENSIONS__"
  80      ;;
  81 *)
  82      ;;
  83 esac
  84
  85 AM_CONDITIONAL([MINGW], [test "$is_mingw" = "yes"])
  86
  87
  88 # backwards support for IRC_CFLAGS
  89 CFLAGS="$IRC_CFLAGS $CFLAGS -Wall"
  90
  91 dnl use directory structure of cached as default (hack)
  92 if test "$libexecdir" = '${exec_prefix}/libexec' &&
  93    test "$localstatedir" = '${prefix}/var'; then
  94         libexecdir='${bindir}'
  95         localstatedir='${prefix}'
  96 fi
  97
  98 AC_TYPE_PID_T
  99 AC_TYPE_SIZE_T
 100 AC_TYPE_SSIZE_T
 101 AC_TYPE_UID_T
 102
 103
 104 dnl Checks for header files.
 105 AC_HEADER_STDC
 106
 107 AC_CHECK_HEADERS([crypt.h unistd.h sys/socket.h sys/stat.h sys/time.h time.h netinet/in.h arpa/inet.h errno.h sys/uio.h spawn.h sys/poll.h sys/epoll.h sys/select.h sys/devpoll.h sys/event.h port.h signal.h sys/signalfd.h sys/timerfd.h])
 108 AC_HEADER_TIME
 109
 110 dnl Networking Functions
 111 dnl ====================
 112
 113 AC_SEARCH_LIBS(socket, [socket],,)
 114
 115
 116 AC_CHECK_MEMBER([struct sockaddr.sa_len], [AC_DEFINE(SOCKADDR_IN_HAS_LEN, 1, [Define to 1 if sockaddr has a 'sa_len'
 117 member.])],,[[
 118 #ifdef HAVE_SYS_TYPES_H
 119 #include <sys/types.h>
 120 #endif
 121 #ifdef HAVE_SYS_SOCKET_H
 122 #include <sys/socket.h>
 123 #endif
 124 #ifdef HAVE_WINSOCK2_H
 125 #include <winsock2.h>
 126 #endif
 127 ]])
 128
 129 AC_CHECK_TYPE([socklen_t], rb_socklen_t=socklen_t,[
 130         AC_MSG_CHECKING([for socklen_t equivalent])
 131         AC_CACHE_VAL([rb_socklen_t],
 132         [
 133         # Systems have either "struct sockaddr *" or
 134         # "void *" as the second argument to getpeername
 135         rb_socklen_t=
 136         for arg2 in "struct sockaddr" void; do
 137                 for t in int size_t unsigned long "unsigned long"; do
 138                         AC_TRY_COMPILE([
 139 #ifdef HAVE_SYS_TYPES_H
 140 #include <sys/types.h>
 141 #endif
 142 #ifdef HAVE_SYS_SOCKET_H
 143 #include <sys/socket.h>
 144 #endif
 145 #ifdef HAVE_WINSOCK2_H
 146 #include <winsock2.h>
 147 #endif
 148 int getpeername (int, $arg2 *, $t *);
 149 ],[
 150 $t len;
 151 getpeername(0,0,&len);
 152 ],[
 153         rb_socklen_t="$t"
 154         break
 155 ])
 156                 done
 157         done
 158
 159         if test "x$rb_socklen_t" = x; then
 160                 AC_MSG_WARN([Cannot find a type to use in place of socklen_t using int])
 161                 rb_socklen_t=int
 162         fi
 163         ])
 164         AC_MSG_RESULT($rb_socklen_t)],
 165         [#include <sys/types.h>
 166 #include <sys/socket.h>])
 167
 168
 169
 170
 171
 172 AC_ARG_ENABLE(ipv6,AC_HELP_STRING([--disable-ipv6],[Disable IPv6 support]),[ipv6=$enableval],[ipv6=yes])
 173
 174 if test x$ipv6 != xyes; then
 175         have_v6="no"
 176 else
 177
 178 have_v6=yes
 179 RB_PROTO_INET6([], [
 180                 AC_MSG_NOTICE([Disabling IPv6 support: PF_INET6 not found])
 181                 have_v6=no
 182                 ])
 183
 184         if test "X$have_v6" = "Xyes"; then
 185         RB_TYPE_STRUCT_SOCKADDR_IN6([], [
 186                 AC_MSG_NOTICE([Disabling IPv6 support: struct sockaddr_in6 not found])
 187                 have_v6=no
 188                 ])
 189         fi
 190
 191 fi
 192
 193 AC_CHECK_TYPES([struct sockaddr_storage],[
 194         rb_have_sockaddr_storage=yes
 195         ],[], [
 196                 #include <sys/types.h>
 197                 #include <sys/socket.h>
 198         ])
 199
 200
 201 save_LIBS=$LIBS
 202 AC_SEARCH_LIBS(crypt, [crypt descrypt],,)
 203 LIBS=$save_LIBS
 204
 205 CRYPT_LIB=$ac_cv_search_crypt
 206
 207 if test "$CRYPT_LIB" = "none required"; then
 208         unset CRYPT_LIB
 209 elif test "$CRYPT_LIB" = no; then
 210         need_crypt=yes;
 211         AC_DEFINE(NEED_CRYPT, 1, [Define if your system needs crypt.])
 212         unset CRYPT_LIB
 213 fi
 214
 215 AM_CONDITIONAL([NEED_CRYPT], [test x"$need_crypt" = "xyes"])
 216
 217
 218 AC_SUBST(CRYPT_LIB)
 219
 220 dnl Check for stdarg.h - if we cant find it, halt configure
 221 AC_CHECK_HEADER(stdarg.h, , [AC_MSG_ERROR([** stdarg.h could not be found - libratbox will not compile without it **])])
 222
 223 AC_CHECK_TYPE([sa_family_t], [],
 224 [AC_DEFINE(sa_family_t, [u_int16_t], [If system does not define sa_family_t, define it here.])],
 225 [[#include <sys/types.h>
 226 #include <sys/socket.h>]])
 227
 228
 229 dnl check for various functions...
 230 AC_CHECK_FUNCS([socketpair gettimeofday writev sendmsg gmtime_r strtok_r usleep posix_spawn strlcpy strlcat strnlen fstat signalfd select poll kevent port_create epoll_ctl arc4random getrusage timerfd_create])
 231
 232 AC_SEARCH_LIBS(nanosleep, rt posix4, AC_DEFINE(HAVE_NANOSLEEP, 1, [Define if you have nanosleep]))
 233 AC_SEARCH_LIBS(timer_create, rt, AC_DEFINE(HAVE_TIMER_CREATE, 1, [Define if you have timer_create]))
 234 RB_CHECK_TIMER_CREATE
 235 RB_CHECK_TIMERFD_CREATE
 236
 237 AC_FUNC_ALLOCA
 238 AC_FUNC_VFORK
 239 AC_FUNC_MMAP
 240
 241 AC_MSG_CHECKING(for /dev/poll)
 242 if test -c "/dev/poll"; then
 243         AC_MSG_RESULT(yes)
 244         AC_DEFINE(HAVE_DEVPOLL, [1], [Define to 1 if you have devpoll])
 245 else
 246         AC_MSG_RESULT(no)
 247 fi
 248
 249
 250 if test "$is_mingw" = "yes"; then
 251         AC_DEFINE(HAVE_WIN32, [1], [Define to 1 if you are on windows])
 252 fi
 253
 254
 255 dnl OpenSSL support
 256 AC_MSG_CHECKING(for OpenSSL)
 257 AC_ARG_ENABLE(openssl,
 258 [AC_HELP_STRING([--enable-openssl[=DIR]],[Enable OpenSSL support (DIR optional).])
 259 AC_HELP_STRING([--disable-openssl],[Disable OpenSSL support.])],
 260 [cf_enable_openssl=$enableval],
 261 [cf_enable_openssl="auto"])
 262
 263 if test "$cf_enable_openssl" != "no" ; then
 264         cf_openssl_basedir=""
 265         if test "$cf_enable_openssl" != "auto" &&
 266         test "$cf_enable_openssl" != "yes" ; then
 267                 dnl Support for --enable-openssl=/some/place
 268                 cf_openssl_basedir="`echo ${cf_enable_openssl} | sed 's/\/$//'`"
 269         else
 270         dnl Do the auto-probe here.  Check some common directory paths.
 271                 for dirs in /usr/local/ssl /usr/pkg /usr/local \
 272                 /usr/local/openssl ; do
 273                         if test -f "${dirs}/include/openssl/opensslv.h" ; then
 274                                 cf_openssl_basedir="${dirs}"
 275                         break
 276                         fi
 277                 done
 278                 unset dirs
 279         fi
 280         dnl Now check cf_openssl_found to see if we found anything.
 281         if test ! -z "$cf_openssl_basedir"; then
 282                 if test -f "${cf_openssl_basedir}/include/openssl/opensslv.h" ; then
 283                         SSL_CFLAGS="-I${cf_openssl_basedir}/include"
 284                         SSL_LIBS="-L${cf_openssl_basedir}/lib"
 285                 else
 286                 dnl OpenSSL wasn't found in the directory specified.  Naughty
 287                 dnl administrator...
 288                 cf_openssl_basedir=""
 289                 fi
 290         else
 291         dnl Check for stock FreeBSD 4.x and 5.x systems, since their files
 292         dnl are in /usr/include and /usr/lib.  In this case, we don't want to
 293         dnl change INCLUDES or LIBS, but still want to enable OpenSSL.
 294         dnl We can't do this check above, because some people want two versions
 295         dnl of OpenSSL installed (stock FreeBSD 4.x/5.x and /usr/local/ssl)
 296         dnl and they want /usr/local/ssl to have preference.
 297                 if test -f "/usr/include/openssl/opensslv.h" ; then
 298                         cf_openssl_basedir="/usr"
 299                 fi
 300         fi
 301
 302         dnl If we have a basedir defined, then everything is okay.  Otherwise,
 303         dnl we have a problem.
 304         if test ! -z "$cf_openssl_basedir"; then
 305                 AC_MSG_RESULT($cf_openssl_basedir)
 306                 cf_enable_openssl="yes"
 307         else
 308                 AC_MSG_RESULT([not found. Specify a correct path?])
 309                 cf_enable_openssl="no"
 310         fi
 311         unset cf_openssl_basedir
 312 else
 313         dnl If --disable-openssl was specified
 314         AC_MSG_RESULT(disabled)
 315 fi
 316
 317 save_CPPFLAGS="$CPPFLAGS"
 318 CPPFLAGS="$CPPFLAGS $SSL_CFLAGS"
 319 save_LIBS="$LIBS"
 320 LIBS="$LIBS $SSL_LIBS"
 321 if test "$cf_enable_openssl" != no; then
 322         dnl Check OpenSSL version (must be 0.9.7 or above!)
 323         AC_MSG_CHECKING(for OpenSSL 0.9.7 or above)
 324         AC_RUN_IFELSE(
 325                 AC_LANG_PROGRAM(
 326                 [#include <openssl/opensslv.h>
 327                 #include <stdlib.h>],
 328                 [[if (OPENSSL_VERSION_NUMBER >= 0x00907000)
 329                 exit(0); else exit(1);]]),
 330         cf_enable_openssl=yes,
 331         cf_enable_openssl=no,
 332         cf_enable_openssl=no)
 333
 334         if test "$cf_enable_openssl" != no; then
 335                 AC_MSG_RESULT(found)
 336         else
 337                 AC_MSG_RESULT(no - OpenSSL support disabled)
 338         fi
 339
 340 fi
 341
 342
 343 if test "$cf_enable_openssl" != no; then
 344         CPPFLAGS="$CPPFLAGS $SSL_LIBS"
 345         AC_CHECK_LIB(crypto, RAND_status,
 346                 [cf_enable_openssl=yes],
 347                 [cf_enable_openssl=no])
 348 fi
 349
 350 if test "$cf_enable_openssl" != no; then
 351         CPPFLAGS="$CPPFLAGS $SSL_LIBS"
 352         AC_CHECK_LIB(ssl, SSL_read,
 353                 [SSL_LIBS="$SSL_LIBS -lssl -lcrypto"],
 354                 [cf_enable_openssl=no], [-lcrypto])
 355 fi
 356
 357
 358
 359 dnl GnuTLS support
 360 AC_MSG_CHECKING(for GnuTLS)
 361 AC_ARG_ENABLE(gnutls,
 362 [AC_HELP_STRING([--enable-gnutls],[Enable GnuTLS support.])
 363 AC_HELP_STRING([--disable-gnutls],[Disable GnuTLS support.])],
 364 [cf_enable_gnutls=$enableval],
 365 [cf_enable_gnutls="auto"])
 366
 367 if test "$cf_enable_gnutls" != no; then
 368        PKG_CHECK_MODULES(GNUTLS, [gnutls], [
 369                cf_enable_gnutls="yes"
 370        ], [cf_enable_gnutls="no"])
 371 fi
 372
 373 if test "$cf_enable_gnutls" = "auto" -a "$cf_enable_openssl" = "yes"; then
 374        cf_enable_gnutls="no"
 375 fi
 376
 377 if test x"$cf_enable_openssl" != xno; then
 378         AC_DEFINE(HAVE_OPENSSL,1,[Has OpenSSL])
 379         GNUTLS_CFLAGS=""
 380         GNUTLS_LIBS=""
 381         SSL_TYPE="openssl"
 382 elif test x"$cf_enable_gnutls" != xno; then
 383         AC_DEFINE(HAVE_GNUTLS, 1, [Has GnuTLS])
 384         SSL_LIBS=""
 385         SSL_CFLAGS=""
 386         SSL_TYPE="gnutls"
 387 fi
 388
 389
 390
 391
 392 CPPFLAGS="$save_CPPFLAGS"
 393 LIBS="$save_LIBS"
 394
 395 dnl End OpenSSL detection
 396
 397
 398
 399
 400 dnl Debug-related options
 401 dnl =====================
 402
 403 AC_ARG_ENABLE(assert,
 404 AC_HELP_STRING([--enable-assert],[Enable assert(). Choose between soft(warnings) and hard(aborts the daemon)]),
 405 [assert=$enableval], [assert=no])
 406
 407 if test "$assert" = no; then
 408         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 409 elif test "$assert" = soft; then
 410         AC_DEFINE(SOFT_ASSERT, 1, [Define this to enable soft asserts.])
 411         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 412 elif test "$assert" = yes; then
 413         assert = "hard";
 414 fi
 415
 416 AC_MSG_CHECKING(if you want to do a profile build)
 417 AC_ARG_ENABLE(profile,
 418 AC_HELP_STRING([--enable-profile],[Enable profiling]),
 419 [profile=$enableval], [profile=no])
 420
 421 if test "$profile" = yes; then
 422         if test "$ac_cv_c_compiler_gnu" = yes; then
 423                 CFLAGS="$CFLAGS -pg -static"
 424                 AC_MSG_RESULT([yes, adding -pg -static])
 425                 AC_DEFINE(RATBOX_PROFILE, 1, [Defined to mark profiling is enabled])
 426         else
 427                 AC_MSG_RESULT([no, profile builds only work with gcc])
 428         fi
 429 else
 430         AC_MSG_RESULT(no)
 431 fi
 432
 433 AC_ARG_ENABLE(balloc,
 434 AC_HELP_STRING([--disable-balloc],[Disable the block allocator.]),
 435 [balloc=$enableval], [balloc=yes])
 436
 437 if test "$balloc" = no; then
 438         AC_DEFINE([NOBALLOC], 1, [Define to 1 if you wish to disable the block allocator.])
 439 fi
 440
 441 AC_ARG_ENABLE(warnings,
 442 AC_HELP_STRING([--enable-warnings],[Enable all sorts of warnings for debugging.]),
 443 [CFLAGS="$CFLAGS -Wall -Werror -Wcast-qual -Wmissing-declarations -Wmissing-prototypes -Wnested-externs -Wshadow -Wwrite-strings -W -Wno-unused -Wunused-function -Wunused-variable"],[])
 444
 445 AC_SUBST(LDFLAGS)
 446 AC_SUBST(PICFLAGS)
 447 AC_SUBST(CFLAGS)
 448 AC_SUBST(SEDOBJ)
 449 AC_SUBST(SSL_CFLAGS)
 450 AC_SUBST(SSL_LIBS)
 451 AC_SUBST(GNUTLS_CFLAGS)
 452 AC_SUBST(GNUTLS_LIBS)
 453
 454 if test "$prefix" = "NONE"; then
 455         AC_DEFINE_UNQUOTED(RB_PREFIX, "$ac_default_prefix", [Prefix where libratbox is installed.])
 456
 457 else
 458
 459 dnl Don't get bitten by Cygwin's stupidity if the user specified
 460 dnl a custom prefix with a trailing slash
 461
 462         prefix=`echo $prefix | sed 's/\/$//'`
 463         AC_DEFINE_UNQUOTED(RB_PREFIX, "$prefix", [Prefix where libratbox is installed.])
 464
 465 fi
 466
 467 AC_SUBST(RB_PREFIX)
 468
 469 AC_CONFIG_COMMANDS([include/librb-config.h],
 470 [
 471         outfile=include/librb-config.h.tmp
 472         cat > $outfile  <<\_______EOF
 473 /*
 474  * librb-config.h: libratbox config file. Please modify configure.ac
 475  */
 476
 477 #ifndef __LIBRB_CONFIG_H
 478 #define __LIBRB_CONFIG_H
 479
 480 _______EOF
 481
 482 if test "x$rb_have_ipv6" = "xyes"; then
 483         echo "#define RB_IPV6 1" >> $outfile
 484 fi
 485
 486 if test "x$rb_windows_h" = "xyes"; then
 487         echo '#define WIN32_LEAN_AND_MEAN 1' >> $outfile
 488         echo '#include <windows.h>' >> $outfile
 489         echo '#include <winsock2.h>' >> $outfile
 490         echo '#include <iphlpapi.h>' >> $outfile
 491 fi
 492
 493 if test "x$rb_alloca_h" = "xyes"; then
 494         echo '#define RB_HAVE_ALLOCA_H 1' >> $outfile
 495 fi
 496
 497 if test "x$rb_header_stdc" = "xyes"; then
 498         echo '#include <stdlib.h>' >> $outfile
 499         echo '#include <stddef.h>' >> $outfile
 500 elif test "x$rb_header_stdlib" = "xyes"; then
 501         echo '#include <stdlib.h>' >> $outfile
 502 fi
 503
 504 if test "x$rb_header_string_h" = "xyes"; then
 505         echo '#include <string.h>' >> $outfile
 506 fi
 507
 508 if test "x$rb_stdint_h" = "xyes"; then
 509         echo '#include <stdint.h>' >> $outfile
 510 fi
 511
 512 if test "x$rb_inttypes_h" = "xyes"; then
 513         echo '#include <inttypes.h>' >> $outfile
 514 fi
 515
 516 if test "x$rb_sys_types_h" = "xyes"; then
 517         echo '#include <sys/types.h>' >> $outfile
 518 fi
 519 if test "x$rb_sys_time_h" = "xyes"; then
 520         echo '#include <sys/time.h>' >> $outfile
 521 fi
 522 if test "x$rb_sys_stat_h" = "xyes"; then
 523         echo '#include <sys/stat.h>' >> $outfile
 524 fi
 525 if test "x$rb_time_h" = "xyes"; then
 526         echo '#include <time.h>' >> $outfile
 527 fi
 528
 529 if test "x$rb_sys_socket_h" = "xyes"; then
 530         echo '#include <sys/socket.h>' >> $outfile
 531 fi
 532
 533 if test "x$rb_netinet_in_h" = "xyes"; then
 534         echo '#include <netinet/in.h>' >> $outfile
 535 fi
 536
 537 if test "x$rb_arpa_inet_h" = "xyes"; then
 538         echo '#include <arpa/inet.h>' >> $outfile
 539 fi
 540
 541 if test "x$rb_unistd_h" = "xyes"; then
 542         echo '#include <unistd.h>' >> $outfile
 543 fi
 544
 545 if test "x$rb_crypt_h" = "xyes"; then
 546         echo '#include <crypt.h>' >> $outfile
 547 fi
 548
 549 if test "x$rb_errno_h" = "xyes"; then
 550         echo '#include <errno.h>' >> $outfile
 551 fi
 552
 553 echo "typedef $rb_socklen_t rb_socklen_t;" >> $outfile
 554
 555
 556 if test "x$rb_sockaddr_sa_len" = "xyes"; then
 557         echo '#define RB_SOCKADDR_HAS_SA_LEN 1' >> $outfile
 558 fi
 559
 560 if test "x$rb_sockaddr_storage" = "xyes"; then
 561         echo '#define rb_sockaddr_storage sockaddr_storage' >> $outfile
 562 else
 563         echo 'struct rb_sockaddr_storage { uint8_t _padding[[128]]; };' >> $outfile
 564 fi
 565
 566 cat >> $outfile <<\_______EOF
 567 #endif /* __LIBRB_CONFIG_H */
 568 _______EOF
 569
 570 if cmp -s $outfile include/librb-config.h; then
 571         AC_MSG_NOTICE([include/librb-config.h is unchanged])
 572         ${rb_rm} -f $outfile
 573 else
 574         ${rb_mv} $outfile include/librb-config.h
 575 fi
 576
 577 ],[
 578         if test x$ac_cv_header_stdc = xyes; then
 579                 rb_header_stdc=yes
 580         fi
 581         if test x$ac_cv_header_stdlib_h = xyes; then
 582                 rb_header_stdlib_h=yes
 583         fi
 584         if test x$ac_cv_header_string_h = xyes; then
 585                 rb_header_string_h=yes
 586         fi
 587         if test x$ac_cv_header_memory_h = xyes; then
 588                 rb_header_memory_h=yes
 589         fi
 590         if test "x${ac_cv_working_alloca_h+set}" = xset ; then
 591                 rb_alloca_h="$ac_cv_working_alloca_h"
 592         else
 593                 rb_alloc_h="$ac_cv_header_alloca_h"
 594         fi
 595         if test x$ac_cv_member_struct_sockaddr_sa_len = xyes; then
 596                 rb_sockaddr_sa_len=yes
 597         fi
 598         if test x$ac_cv_header_sys_socket_h = xyes; then
 599                 rb_sys_socket_h=yes
 600         fi
 601         if test x$ac_cv_header_sys_types_h = xyes; then
 602                 rb_sys_types_h=yes
 603         fi
 604         if test x$ac_cv_header_sys_stat_h = xyes; then
 605                 rb_sys_stat_h=yes
 606         fi
 607         if test x$ac_cv_header_sys_time_h = xyes; then
 608                 rb_sys_time_h=yes
 609         fi
 610         if test x$ac_cv_header_time = xyes; then
 611                 rb_time_h=yes
 612         fi
 613
 614         if test x$ac_cv_header_stdint_h = xyes; then
 615                 rb_stdint_h=yes
 616         fi
 617         if test x$ac_cv_header_inttypes_h = xyes; then
 618                 rb_inttypes_h=yes
 619         fi
 620         if test x$ac_cv_header_netinet_in_h = xyes; then
 621                 rb_netinet_in_h=yes
 622         fi
 623
 624         if test x$ac_cv_header_crypt_h = xyes; then
 625                 rb_crypt_h=yes
 626         fi
 627         if test x$ac_cv_header_errno_h = xyes; then
 628                 rb_errno_h=yes
 629         fi
 630         if test x$ac_cv_header_unistd_h = xyes; then
 631                 rb_unistd_h=yes
 632         fi
 633         if test x$ac_cv_header_windows_h = xyes; then
 634                 rb_windows_h=yes
 635         fi
 636         if test x$ac_cv_header_winsock2_h = xyes; then
 637                 rb_winsock2_h=yes
 638         fi
 639
 640         rb_socklen_t=$rb_socklen_t
 641
 642         if test "x$rb_have_sockaddr_storage" = "xyes"; then
 643                 rb_sockaddr_storage="yes"
 644         else
 645                 rb_sockaddr_storage="no"
 646         fi
 647
 648         rb_have_ipv6="$have_v6"
 649
 650         rb_mv="$MV"
 651         rb_rm="$RM"
 652
 653 ]
 654
 655
 656 )
 657
 658
 659 AC_CONFIG_FILES(                \
 660         src/Makefile            \
 661         Makefile                \
 662         libratbox.pc    \
 663 )
 664
 665 AC_OUTPUT
 666
 667 dnl Make it look sexay!
 668
 669 echo
 670 echo "Compiling $PACKAGE_NAME $PACKAGE_VERSION"
 671 echo
 672
 673 echo "Installing into: $prefix"
 674
 675 echo "IPv6 support ................... $have_v6"
 676 echo "Assert debugging ............... $assert"
 677 echo "Block allocator ................ $balloc"
 678 echo "SSL Type........................ $SSL_TYPE"
 679 echo
 680