configure.ac

   1 dnl TODO: clean up all the OpenSSL and shared module checking stuff;
   2 dnl the most major changes have already been made and it looks like
   3 dnl said functions need to be just about as complex as they already are.
   4
   5 AC_PREREQ(2.60)
   6
   7 AC_INIT([solanum], [1.0-dev])
   8
   9 AC_LANG(C)
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_GNU_SOURCE
  12
  13 AC_PROG_CC_C99
  14
  15 if test x"$ac_cv_prog_cc_c99" = "xno"; then
  16         AC_ERROR([solanum requires a C99 capable compiler])
  17 fi
  18
  19 AC_PREFIX_DEFAULT($HOME/ircd)
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_HEADER(include/setup.h)
  22
  23 AC_CONFIG_SUBDIRS([librb])
  24 AC_CONFIG_AUX_DIR([libltdl/config])
  25
  26 AM_INIT_AUTOMAKE([subdir-objects])
  27 AM_SILENT_RULES([yes])
  28 AM_PROG_AR
  29
  30 LT_INIT([dlopen disable-static])
  31 LT_CONFIG_LTDL_DIR([libltdl])
  32 LTDL_INIT
  33
  34 build_ltdl=$with_included_ltdl
  35 AM_CONDITIONAL([BUILD_LTDL], [test x"$build_ltdl" = x"yes"])
  36
  37 case "$host_os" in
  38 *cygwin*)
  39      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
  40      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  41      ;;
  42 *mingw* | *msys*)
  43      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
  44      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  45      AC_CHECK_HEADER(winsock2.h, , [AC_MSG_ERROR([** MinGW and no winsock2.h.  I give up.])])
  46      LIBS="$LIBS -lws2_32 -liphlpapi"
  47      is_mingw="yes"
  48      ;;
  49 *)
  50      ;;
  51 esac
  52
  53 AM_CONDITIONAL([MINGW], [test "$is_mingw" = "yes"])
  54
  55 if test "$ac_cv_c_compiler_gnu" = yes; then
  56         IRC_CFLAGS="$IRC_CFLAGS -O0 -Wall"
  57 fi
  58
  59 dnl If we support -g, use it!
  60 if test "$ac_cv_prog_cc_g" = yes; then
  61         IRC_CFLAGS="$IRC_CFLAGS -g"
  62 fi
  63
  64 dnl check for /dev/null so we can use it to hold evil fd's
  65 AC_MSG_CHECKING([for /dev/null])
  66 if test -c /dev/null ; then
  67         AC_DEFINE(PATH_DEVNULL, "/dev/null", [Path to /dev/null])
  68         AC_MSG_RESULT(yes)
  69 else
  70         AC_DEFINE(PATH_DEVNULL, "devnull.log", [Path to /dev/null])
  71         AC_MSG_RESULT(no - using devnull.log)
  72 fi
  73
  74 dnl jdc -- If CFLAGS is defined, best use it everywhere...
  75 dnl NOTE: jv says it must be added to the *END*, because things like
  76 dnl "gcc -O9 -O2" will result in -O2 getting preference.  How stupid.
  77 if test ! -z "$CFLAGS"; then
  78         IRC_CFLAGS="$IRC_CFLAGS $CFLAGS"
  79 fi
  80
  81 AC_ISC_POSIX
  82 AC_C_INLINE
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PATH_PROG(RM, rm)
  86 AC_PATH_PROG(CP, cp)
  87 AC_PATH_PROG(MV, mv)
  88 AC_PATH_PROG(LN, ln)
  89 AC_PATH_PROG(SED, sed)
  90 AC_PATH_PROG(AR, ar)
  91 AC_PATH_PROG(LD, ld)
  92 AC_PATH_PROG(RANLIB, ranlib)
  93 AC_PATH_PROG(TOUCH, touch)
  94
  95 AC_PROG_YACC
  96
  97 dnl AC_PROG_YACC defaults to yacc unconditionally if nothing can be found
  98 if test "$YACC" = "yacc" -a -z "`which $YACC 2>/dev/null`"; then
  99         AC_MSG_ERROR([could not locate a suitable parser generator; install bison, yacc, or byacc])
 100 fi
 101
 102 AC_PROG_LEX
 103
 104 if test "$LEX" = ":"; then
 105         AC_MSG_ERROR([could not locate a suitable lexical generator, install flex or lex.])
 106 fi
 107
 108 AC_ARG_ENABLE([fhs-paths],
 109         [AS_HELP_STRING([--enable-fhs-paths], [Use more FHS-like pathnames (for packagers).])],
 110         [],
 111         [dnl detect if the user appears to want --enable-fhs-paths
 112         AS_IF([test "$libexecdir" = '${exec_prefix}/libexec' && \
 113                 test "$localstatedir" = '${prefix}/var' && \
 114                 test "$libdir" = '${exec_prefix}/lib'],
 115                 [enable_fhs_paths=no],
 116                 [enable_fhs_paths=yes])
 117         ])
 118 dnl use directory structure of cached as default (hack)
 119 AS_IF([test "x$enable_fhs_paths" = "xyes"],
 120         [dnl Avoid name collisions.
 121         pkglibexecdir='${libexecdir}/${PACKAGE_TARNAME}'
 122         rundir=${rundir-'${prefix}/run'}
 123         pkgrundir='${rundir}/${PACKAGE_TARNAME}'
 124         pkglocalstatedir='${localstatedir}/${PACKAGE_TARNAME}'
 125         AC_DEFINE([ENABLE_FHS_PATHS], [1], [Uncomment if FHS pathnames are enabled])],
 126         [libexecdir='${bindir}'
 127         pkglibexecdir='${libexecdir}'
 128         rundir='${sysconfdir}'
 129         pkgrundir='${rundir}'
 130         localstatedir='${prefix}'
 131         pkglocalstatedir='${sysconfdir}'])
 132 pkglibdir='${libdir}/${PACKAGE_TARNAME}'
 133 AC_SUBST([pkglibdir])
 134 AC_SUBST([rundir])
 135 AC_SUBST([pkgrundir])
 136 AC_SUBST([pkglocalstatedir])
 137 AC_DEFINE_DIR([PKGLOCALSTATEDIR], [pkglocalstatedir], [[Directory in which to store state, such as ban database]])
 138 AC_SUBST([pkglibexecdir])
 139 AC_DEFINE_DIR([PKGLIBEXECDIR], [pkglibexecdir], [Directory where binaries the IRCd itself spawns live])
 140
 141 dnl Checks for header files.
 142 AC_HEADER_STDC
 143 AC_HEADER_STDBOOL
 144
 145 AC_CHECK_HEADERS([crypt.h sys/resource.h sys/param.h errno.h sys/syslog.h stddef.h sys/wait.h wait.h sys/epoll.h sys/uio.h machine/endian.h])
 146
 147 dnl Stuff that the memory manager (imalloc) depends on
 148 dnl ==================================================
 149
 150 AC_C_CONST
 151 if test "$ac_cv_header_machine_endian_h" = "no" ; then
 152     AC_C_BIGENDIAN
 153 fi
 154 AC_TYPE_PID_T
 155 AC_TYPE_SIZE_T
 156 AC_CHECK_SIZEOF(short)
 157 AC_CHECK_SIZEOF(int)
 158 AC_CHECK_SIZEOF(long)
 159 AC_CHECK_SIZEOF(long long)
 160
 161 dnl Networking Functions
 162 dnl ====================
 163
 164 AC_SEARCH_LIBS(socket, [socket ws2_32], , [AC_MSG_ERROR([You have no socket()! Aborting.])])
 165
 166 dnl SunOS/Solaris required libnsl for inet_ntoa()
 167 if test x"$SUN" = xyes; then
 168         AC_SEARCH_LIBS(inet_ntoa, nsl,, [AC_MSG_ERROR([libnsl not found! Aborting.])])
 169 fi
 170
 171 AC_SEARCH_LIBS(crypt, [crypt descrypt],,)
 172
 173 CRYPT_LIB=$ac_cv_search_crypt
 174
 175 if test "$CRYPT_LIB" = "none required"; then
 176         unset CRYPT_LIB
 177 elif test "$CRYPT_LIB" = no; then
 178         unset CRYPT_LIB
 179 fi
 180
 181 AC_SUBST(CRYPT_LIB)
 182
 183 AC_C_BIGENDIAN
 184
 185 dnl Check for stdarg.h - if we can't find it, halt configure
 186 AC_CHECK_HEADER(stdarg.h, , [AC_MSG_ERROR([** stdarg.h could not be found - solanum will not compile without it **])])
 187 AC_CHECK_FUNCS([strlcat strlcpy])
 188
 189 AC_TYPE_INT16_T
 190 AC_TYPE_INT32_T
 191
 192 AC_CHECK_TYPE([sa_family_t], [],
 193 [AC_DEFINE(sa_family_t, [u_int16_t], [If system does not define sa_family_t, define it here.])],
 194 [[#include <sys/types.h>
 195 #include <sys/socket.h>]])
 196
 197 AC_CHECK_TYPES([uintptr_t])
 198
 199 dnl check for various functions...
 200 AC_CHECK_FUNCS([snprintf vsnprintf socketpair mmap gettimeofday strdup strndup ])
 201
 202 AC_FUNC_ALLOCA
 203
 204 dnl Specialized functions checks
 205 dnl ============================
 206
 207 dnl check for nanosleep
 208 AC_CHECK_FUNC(nanosleep,,[AC_CHECK_LIB(rt,nanosleep,
 209                  LIBS="${LIBS} -lrt",
 210                  [AC_CHECK_LIB(posix4,nanosleep, LIBS="${LIBS} -lposix4"
 211                  )])])
 212 if test x$ac_cv_func_nanosleep = xno && test x$ac_cv_lib_posix4_nanosleep = xno  && test x$ac_cv_lib_rt_nanosleep = xno
 213 then
 214          AC_MSG_RESULT("nanosleep not found..using select for delay")
 215 else
 216          AC_DEFINE([HAVE_NANOSLEEP], 1, [Define if nanosleep exists])
 217 fi
 218
 219 dnl OpenSSL support
 220 AC_MSG_CHECKING(for OpenSSL)
 221 AC_ARG_ENABLE(openssl,
 222 [AC_HELP_STRING([--enable-openssl[=DIR]],[Enable OpenSSL support (DIR optional).])
 223 AC_HELP_STRING([--disable-openssl],[Disable OpenSSL support.])],
 224 [cf_enable_openssl=$enableval],
 225 [cf_enable_openssl="auto"])
 226
 227 if test "$cf_enable_openssl" != "no" ; then
 228         cf_openssl_basedir=""
 229         if test "$cf_enable_openssl" != "auto" &&
 230         test "$cf_enable_openssl" != "yes" ; then
 231                 dnl Support for --enable-openssl=/some/place
 232                 cf_openssl_basedir="`echo ${cf_enable_openssl} | sed 's/\/$//'`"
 233         else
 234         dnl Do the auto-probe here.  Check some common directory paths.
 235                 for dirs in /usr/local/ssl /usr/pkg /usr/local \
 236                 /usr/local/openssl ; do
 237                         if test -f "${dirs}/include/openssl/opensslv.h" ; then
 238                                 cf_openssl_basedir="${dirs}"
 239                         break
 240                         fi
 241                 done
 242                 unset dirs
 243         fi
 244         dnl Now check cf_openssl_found to see if we found anything.
 245         if test ! -z "$cf_openssl_basedir"; then
 246                 if test -f "${cf_openssl_basedir}/include/openssl/opensslv.h" ; then
 247                         SSL_INCLUDES="-I${cf_openssl_basedir}/include"
 248                         SSL_LIBS="-L${cf_openssl_basedir}/lib"
 249                 else
 250                 dnl OpenSSL wasn't found in the directory specified.  Naughty
 251                 dnl administrator...
 252                 cf_openssl_basedir=""
 253                 fi
 254         else
 255         dnl Check for stock FreeBSD 4.x and 5.x systems, since their files
 256         dnl are in /usr/include and /usr/lib.  In this case, we don't want to
 257         dnl change INCLUDES or LIBS, but still want to enable OpenSSL.
 258         dnl We can't do this check above, because some people want two versions
 259         dnl of OpenSSL installed (stock FreeBSD 4.x/5.x and /usr/local/ssl)
 260         dnl and they want /usr/local/ssl to have preference.
 261                 if test -f "/usr/include/openssl/opensslv.h" ; then
 262                         cf_openssl_basedir="/usr"
 263                 fi
 264         fi
 265
 266         dnl If we have a basedir defined, then everything is okay.  Otherwise,
 267         dnl we have a problem.
 268         if test ! -z "$cf_openssl_basedir"; then
 269                 AC_MSG_RESULT($cf_openssl_basedir)
 270                 cf_enable_openssl="yes"
 271         else
 272                 AC_MSG_RESULT([not found. Specify a correct path?])
 273                 cf_enable_openssl="no"
 274         fi
 275         unset cf_openssl_basedir
 276 else
 277         dnl If --disable-openssl was specified
 278         AC_MSG_RESULT(disabled)
 279 fi
 280
 281 save_CPPFLAGS="$CPPFLAGS"
 282 CPPFLAGS="$CPPFLAGS $SSL_INCLUDES"
 283 save_LIBS="$LIBS"
 284 LIBS="$LIBS $SSL_LIBS"
 285 if test "$cf_enable_openssl" != no; then
 286         dnl Check OpenSSL version (must be 0.9.6 or above!)
 287         AC_MSG_CHECKING(for OpenSSL 0.9.6 or above)
 288         AC_RUN_IFELSE(
 289                 [AC_LANG_PROGRAM(
 290                 [#include <openssl/opensslv.h>
 291                 #include <stdlib.h>],
 292                 [[if ( OPENSSL_VERSION_NUMBER >= 0x00906000)
 293                 exit(0); else exit(1);]])],
 294         cf_openssl_version_ok=yes,
 295         cf_openssl_version_ok=no,
 296         cf_openssl_version_ok=no)
 297
 298         if test "$cf_openssl_version_ok" = yes; then
 299                 AC_MSG_RESULT(found)
 300
 301                 dnl Work around pmake/gmake conditional incompatibilities
 302                 AC_SUBST(ENCSPEED, encspeed)
 303
 304                 dnl Do all the HAVE_LIBCRYPTO magic -- and check for ciphers
 305                 CPPFLAGS="$CPPFLAGS $SSL_LIBS"
 306                 AC_CHECK_LIB(crypto, RSA_free)
 307                 SSL_LIBS="$SSL_LIBS -lcrypto"
 308                 SSL_SRCS_ENABLE='$(SSL_SRCS)'
 309         else
 310                 AC_MSG_RESULT(no - OpenSSL support disabled)
 311         fi
 312 fi
 313
 314 CPPFLAGS="$save_CPPFLAGS"
 315 LIBS="$save_LIBS"
 316
 317 dnl End OpenSSL detection
 318
 319
 320 dnl Specialized functions and libraries
 321 dnl ===================================
 322
 323 AC_ARG_ENABLE(hyperscan,
 324 AC_HELP_STRING([--disable-hyperscan],[Disable hyperscan support]),
 325 [hyperscan=$enableval],[hyperscan=yes])
 326
 327 AS_IF([test "$hyperscan" = yes], [
 328         save_CPPFLAGS="$CPPFLAGS"
 329         save_LIBS="$LIBS"
 330         PKG_CHECK_MODULES([HS], [libhs >= 4], [], [hyperscan=no])
 331         CPPFLAGS="$CPPFLAGS $HS_CFLAGS"
 332         LIBS="$LIBS $HS_LIBS"
 333         AC_CHECK_HEADER([hs_common.h], [], [hyperscan=no])
 334         AC_CHECK_FUNC([hs_scan], [], [hyperscan=no])
 335 ])
 336
 337 AS_IF([test "$hyperscan" = no], [
 338         CPPFLAGS="$save_CPPFLAGS"
 339         LIBS="$save_LIBS"
 340 ])
 341
 342 AM_CONDITIONAL([HAVE_HYPERSCAN], [test "$hyperscan" = "yes"])
 343
 344
 345 AC_ARG_WITH(zlib-path,
 346 AC_HELP_STRING([--with-zlib-path=DIR],[Path to libz.so for ziplinks support.]),
 347 [LIBS="$LIBS -L$withval"],)
 348
 349 AC_ARG_ENABLE(zlib,
 350 AC_HELP_STRING([--disable-zlib],[Disable ziplinks support]),
 351 [zlib=$enableval],[zlib=yes])
 352
 353 if test "$zlib" = yes; then
 354
 355 AC_CHECK_HEADER(zlib.h, [
 356         AC_CHECK_LIB(z, zlibVersion,
 357         [
 358                 AC_SUBST(ZLIB_LD, -lz)
 359                 AC_DEFINE(HAVE_LIBZ, 1, [Define to 1 if zlib (-lz) is available.])
 360         ], zlib=no)
 361 ], zlib=no)
 362
 363 fi
 364
 365 AC_ARG_WITH(sctp-path,
 366 AC_HELP_STRING([--with-sctp-path=DIR],[Path to libsctp.so for SCTP support.]),
 367 [LIBS="$LIBS -L$withval"],)
 368
 369 AC_ARG_ENABLE(sctp,
 370 AC_HELP_STRING([--disable-sctp],[Disable SCTP support]),
 371 [sctp=$enableval],[sctp=yes])
 372
 373 if test "$sctp" = yes; then
 374
 375 AC_CHECK_HEADER(netinet/sctp.h, [
 376         AC_CHECK_LIB(sctp, sctp_bindx,
 377         [
 378                 AC_SUBST(LIBSCTP_LD, -lsctp)
 379                 AC_DEFINE(HAVE_LIBSCTP, 1, [Define to 1 if libsctp (-lsctp) is available.])
 380         ], sctp=no)
 381 ], sctp=no)
 382
 383 fi
 384
 385 dnl Check for shared sqlite
 386 dnl ======================
 387 PKG_CHECK_MODULES(SQLITE, [sqlite3], [], AC_ERROR([sqlite3 is required]))
 388
 389 AC_SUBST(SQLITE_LD, "$SQLITE_LIBS")
 390 AC_SUBST(SQLITE_INCLUDES, "$SQLITE_CFLAGS")
 391
 392 dnl **********************************************************************
 393 dnl Check for --with-confdir [deprecated, use --sysconfdir instead]
 394 dnl **********************************************************************
 395
 396 AC_ARG_WITH([confdir],
 397         [AC_HELP_STRING([--with-confdir=DIR],
 398                [Directory to install config files [deprecated, use --sysconfdir instead].])],
 399         [ sysconfdir=`echo $withval | sed 's/\/$//'` ],
 400         [ confdir='${sysconfdir}' ])
 401 AC_DEFINE_DIR([ETC_DIR], [sysconfdir], [Prefix where config files are installed.])
 402
 403 dnl **********************************************************************
 404 dnl Check for --with-logdir
 405 dnl **********************************************************************
 406
 407 AC_MSG_CHECKING([whether to modify logdir])
 408 AC_ARG_WITH(logdir,
 409 AC_HELP_STRING([--with-logdir=DIR],
 410                [Directory where to write logfiles.]),
 411                [ logdir=`echo $withval | sed 's/\/$//'`
 412                  AC_MSG_RESULT(yes)],
 413                [ AS_IF([test "x$enable_fhs_paths" = "xyes"],
 414                         [logdir='${localstatedir}/log/${PACKAGE_TARNAME}'],
 415                         [logdir='${prefix}/logs'])
 416                  AC_MSG_RESULT(no)])
 417 AC_DEFINE_DIR([LOG_DIR], [logdir], [Prefix where to write logfiles.])
 418 AC_SUBST_DIR([logdir])
 419
 420 dnl **********************************************************************
 421 dnl Check for --with-helpdir
 422 dnl **********************************************************************
 423
 424 AC_MSG_CHECKING([whether to modify helpdir])
 425 AC_ARG_WITH(helpdir,
 426 AC_HELP_STRING([--with-helpdir=DIR],
 427                [Directory to install help files.]),
 428                [ helpdir=`echo $withval | sed 's/\/$//'`
 429                  AC_MSG_RESULT(yes) ],
 430                [ AS_IF([test "x$enable_fhs_paths" = "xyes"],
 431                         [helpdir='${datadir}/${PACKAGE_TARNAME}/help'],
 432                         [helpdir='${prefix}/help'])
 433                  AC_MSG_RESULT(no) ])
 434 AC_DEFINE_DIR([HELP_DIR], [helpdir], [Prefix where help files are installed.])
 435 AC_SUBST_DIR([helpdir])
 436
 437 dnl **********************************************************************
 438 dnl Check for --with-moduledir
 439 dnl **********************************************************************
 440
 441 AC_MSG_CHECKING([whether to modify moduledir])
 442 AC_ARG_WITH(moduledir,
 443         [AC_HELP_STRING([--with-moduledir=DIR],
 444                [Directory to install modules.])],
 445                [ moduledir=`echo $withval | sed 's/\/$//'`
 446                  AC_MSG_RESULT(yes)],
 447                [ AS_IF([test "x$enable_fhs_paths" = "xyes"],
 448                         [moduledir='${pkglibdir}/modules'],
 449                         [moduledir='${prefix}/modules'])
 450                  AC_MSG_RESULT(no)
 451                 ])
 452 AC_DEFINE_DIR(MODULE_DIR, moduledir, [Prefix where modules are installed.])
 453 AC_SUBST_DIR([moduledir])
 454
 455 dnl Check for --with-rundir
 456
 457 AC_MSG_CHECKING([whether or modify rundir])
 458 AC_ARG_WITH([rundir],
 459         [AC_HELP_STRING([--with-rundir=DIR],
 460                 [Directory in which to store pidfile.])],
 461         [AC_MSG_RESULT([yes])
 462         rundir=`echo $withval | sed 's/\/$//'`],
 463         [AC_MSG_RESULT([no])
 464         AS_IF([test "x$enable_fhs_paths" = "xyes"],
 465                 [rundir='${prefix}/run'],
 466                 [rundir='${sysconfdir}'])])
 467 AC_SUBST([rundir])
 468 AC_DEFINE_DIR([PKGRUNDIR], [pkgrundir], [Directory to store pidfile in.])
 469
 470 dnl Installed utility program prefixes (does not affect binaries
 471 dnl installed into pkglibexecdir)
 472 AC_MSG_CHECKING([for program prefix])
 473 AC_ARG_WITH([program-prefix],
 474         [AS_HELP_STRING([--with-program-prefix=], [If set, programs installed into PATH will be installed with names prefixed by this prefix.])],
 475         [test "x$with_program_prefix" = "xno" && with_program_prefix=],
 476         [with_program_prefix=])
 477 AC_MSG_RESULT(["$with_program_prefix"])
 478 PROGRAM_PREFIX="$with_program_prefix"
 479 AC_SUBST([PROGRAM_PREFIX])
 480 AC_DEFINE_UNQUOTED([PROGRAM_PREFIX], ["$with_program_prefix"], [String with which all programs intended to be in PATH are prefixed.])
 481
 482 dnl **********************************************************************
 483 dnl Branding
 484 dnl **********************************************************************
 485
 486 AC_MSG_CHECKING([whether custom branding is requested])
 487 AC_ARG_WITH(custom-branding,
 488 AC_HELP_STRING([--with-custom-branding=NAME],
 489                [Custom branding name.]),
 490                [BRANDING_NAME=$withval
 491                 AC_MSG_RESULT([yes])],
 492                [BRANDING_NAME=$PACKAGE_NAME
 493                 AC_MSG_RESULT([no])]
 494 )
 495
 496 AC_MSG_CHECKING([whether a custom version is requested])
 497 AC_ARG_WITH(custom-version,
 498 AC_HELP_STRING([--with-custom-version=NAME],
 499                [Custom version branding.]),
 500                [BRANDING_VERSION=$withval
 501                 AC_MSG_RESULT([yes])],
 502                [BRANDING_VERSION=$PACKAGE_VERSION
 503                 AC_MSG_RESULT([no])]
 504 )
 505
 506 AC_DEFINE_UNQUOTED(BRANDING_NAME, ["$BRANDING_NAME"], [Custom branding name.])
 507 AC_DEFINE_UNQUOTED(BRANDING_VERSION, ["$BRANDING_VERSION"], [Custom branding name.])
 508
 509 if test "x$BRANDING_NAME" != "x$PACKAGE_NAME"; then
 510         AC_DEFINE(CUSTOM_BRANDING, 1, [Define if custom branding is enabled.])
 511 fi
 512
 513 dnl **********************************************************************
 514 dnl Enable oper chghost
 515 dnl **********************************************************************
 516
 517 AC_ARG_ENABLE(oper-chghost,
 518 AC_HELP_STRING([--enable-oper-chghost],[Enable opers to use the CHGHOST command]),
 519 [operchghost=$enableval],[operchghost=no])
 520
 521 if test "$operchghost" = yes; then
 522         AC_DEFINE(ENABLE_OPER_CHGHOST, 1, [Define this to enable opers to use the CHGHOST command.])
 523 fi
 524
 525 dnl Debug-related options
 526 dnl =====================
 527
 528 AC_ARG_ENABLE(assert,
 529 AC_HELP_STRING([--enable-assert],[Enable assert(). Choose between soft(warnings) and hard(aborts the daemon)]),
 530 [assert=$enableval], [assert=no])
 531
 532 if test "$assert" = no; then
 533         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 534 elif test "$assert" = soft; then
 535         AC_DEFINE(SOFT_ASSERT, 1, [Define this to enable soft asserts.])
 536         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 537 elif test "$assert" = yes; then
 538         assert = "hard";
 539 fi
 540
 541 AC_MSG_CHECKING(if you want to do a profile build)
 542 AC_ARG_ENABLE(profile,
 543 AC_HELP_STRING([--enable-profile],[Enable profiling]),
 544 [profile=$enableval], [profile=no])
 545
 546 if test "$profile" = yes; then
 547         if test "$ac_cv_c_compiler_gnu" = yes; then
 548                 IRC_CFLAGS="$IRC_CFLAGS -pg"
 549                 AC_MSG_RESULT([yes, adding -pg])
 550                 AC_DEFINE(SOLANUM_PROFILE, 1, [Define this if you are profiling.])
 551         else
 552                 AC_MSG_RESULT([no, profile builds only work with gcc])
 553         fi
 554 else
 555         AC_MSG_RESULT(no)
 556 fi
 557
 558 AC_DEFINE([NICKNAMEHISTORYLENGTH], 15000, [Size of the WHOWAS array.])
 559 AC_DEFINE([CHANNEL_HEAP_SIZE], 8192, [Size of the channel heap.])
 560 AC_DEFINE([BAN_HEAP_SIZE], 4096, [Size of the ban heap.])
 561 AC_DEFINE([CLIENT_HEAP_SIZE], 8192, [Size of the client heap.])
 562 AC_DEFINE([LCLIENT_HEAP_SIZE], 1024, [Size of the local client heap.])
 563 AC_DEFINE([PCLIENT_HEAP_SIZE], 256, [Size of the pre-client heap.])
 564 AC_DEFINE([USER_HEAP_SIZE], 8192, [Size of the user heap.])
 565 AC_DEFINE([DNODE_HEAP_SIZE], 8192, [Size of the dlink_node heap.])
 566 AC_DEFINE([TOPIC_HEAP_SIZE], 4096, [Size of the topic heap.])
 567 AC_DEFINE([LINEBUF_HEAP_SIZE], 2048, [Size of the linebuf heap.])
 568 AC_DEFINE([MEMBER_HEAP_SIZE], 32768, [Sizeof member heap.])
 569 AC_DEFINE([ND_HEAP_SIZE], 512, [Size of the nick delay heap.])
 570 AC_DEFINE([CONFITEM_HEAP_SIZE], 256, [Size of the confitem heap.])
 571 AC_DEFINE([MONITOR_HEAP_SIZE], 1024, [Size of the monitor heap.])
 572 AC_DEFINE([FD_HEAP_SIZE], 1024, [Size of fd heap.])
 573 AC_DEFINE([AWAY_HEAP_SIZE], 512, [Size of away heap.])
 574
 575 AC_ARG_WITH(nicklen,
 576 AC_HELP_STRING([--with-nicklen=LENGTH],[Set the upper-bound nick length to LENGTH (default 31, max 50)]),
 577 [
 578   if ! expr "$withval" + 0 >/dev/null 2>&1; then
 579         AC_ERROR([NICKLEN must be a numeric value])
 580   fi
 581   if test $withval -gt 50; then
 582         NICKLEN=50
 583         AC_MSG_WARN([NICKLEN has a hard limit of 50. Setting NICKLEN=50])
 584   elif test $withval -lt 9; then
 585         NICKLEN=9
 586         AC_MSG_WARN([NICKLEN has a lower limit of 9. Setting NICKLEN=9])
 587   else
 588         NICKLEN="$withval"
 589   fi
 590 ], [NICKLEN=31])
 591
 592 AC_ARG_WITH(topiclen,
 593 AC_HELP_STRING([--with-topiclen=NUMBER],[Set the max topic length to NUMBER (default 390, max 390)]),
 594 [
 595  if test $withval -gt 390; then
 596         TOPICLEN=390
 597         AC_MSG_WARN([TOPICLEN has a hard limit of 390. Setting TOPICLEN=390])
 598  else
 599         TOPICLEN=$withval
 600  fi
 601 ], [TOPICLEN=390])
 602
 603 AC_DEFINE_UNQUOTED(TOPICLEN, ${TOPICLEN}, [Maximum topic length (<=390)])
 604 AC_DEFINE_UNQUOTED(NICKLEN, (${NICKLEN}+1), [Nickname length])
 605
 606
 607 AC_ARG_WITH(asan,
 608 AC_HELP_STRING([--with-asan],[Build with Address Sanitizer]),
 609 [
 610     CFLAGS="$CFLAGS -fsanitize=address"
 611     LDFLAGS="$LDFLAGS -fsanitize=address"
 612 ])
 613
 614 # rpath, for finding librb.so at run time
 615 hold_ldflags=$LDFLAGS
 616 AC_MSG_CHECKING(for the ld -rpath flag)
 617 LDFLAGS="${LDFLAGS} -Wl,-rpath=${libdir}"
 618 AC_LINK_IFELSE([AC_LANG_PROGRAM([],[int i;])], found=yes, found=no)
 619 LDFLAGS=$hold_ldflags
 620 AC_MSG_RESULT($found)
 621 if test "$found" = yes; then
 622         LDFLAGS="${LDFLAGS} -Wl,-rpath=\${libdir}"
 623 fi
 624
 625 # This must be down here, or it will mess up checks like the ones
 626 # for -Wl,-export-dynamic
 627 # -- jilles
 628 CWARNS=""
 629 AC_ARG_ENABLE(warnings,
 630 AC_HELP_STRING([--enable-warnings],[Enable all sorts of warnings for debugging.]),
 631 [
 632 IRC_CFLAGS="$IRC_CFLAGS -O0"
 633 CFLAGS="$IRC_CFLAGS"
 634
 635 SOLANUM_C_GCC_TRY_FLAGS([-Wall], solanum_cv_c_gcc_w_all)
 636 SOLANUM_C_GCC_TRY_FLAGS([-Wpointer-arith], solanum_cv_c_gcc_w_pointer_arith)
 637 SOLANUM_C_GCC_TRY_FLAGS([-Wimplicit -Wnested-externs], solanum_cv_c_gcc_w_implicit)
 638 SOLANUM_C_GCC_TRY_FLAGS([-Wcast-align], solanum_cv_c_gcc_w_cast_align)
 639 SOLANUM_C_GCC_TRY_FLAGS([-Wcast-qual], solanum_cv_c_gcc_w_cast_qual)
 640 SOLANUM_C_GCC_TRY_FLAGS([-Wwrite-strings], solanum_cv_c_gcc_w_write_strings)
 641 SOLANUM_C_GCC_TRY_FLAGS([-Werror-implicit-function-declaration], solanum_cv_c_gcc_w_error_implicit_function_declaration)
 642 SOLANUM_C_GCC_TRY_FLAGS([-Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations], solanum_cv_c_gcc_prototypes)
 643 SOLANUM_C_GCC_TRY_FLAGS([-Wparentheses], solanum_cv_c_gcc_parentheses)
 644 SOLANUM_C_GCC_TRY_FLAGS([-W -Wno-unused], solanum_cv_c_gcc_w)
 645 SOLANUM_C_GCC_TRY_FLAGS([-Wextra], solanum_cv_c_gcc_w_extra)
 646 SOLANUM_C_GCC_TRY_FLAGS([-Wshadow], solanum_cv_c_gcc_w_shadow)
 647 SOLANUM_C_GCC_TRY_FLAGS([-Wmissing-noreturn], solanum_cv_c_gcc_w_missing_noreturn)
 648 SOLANUM_C_GCC_TRY_FLAGS([-Wundef], solanum_cv_c_gcc_w_undef)
 649 SOLANUM_C_GCC_TRY_FLAGS([-Wpacked], solanum_cv_c_gcc_w_packed)
 650 SOLANUM_C_GCC_TRY_FLAGS([-Wnested-externs], solanum_cv_c_gcc_w_nested_externs)
 651 SOLANUM_C_GCC_TRY_FLAGS([-Wunused-function -Wunused-label -Wunused-value -Wunused-variable], solanum_cv_c_gcc_w_unused)
 652 SOLANUM_C_GCC_TRY_FLAGS([-Wredundant-decls], solanum_cv_c_gcc_w_redundant_decls)
 653 SOLANUM_C_GCC_TRY_FLAGS([-Wfloat-equal], solanum_cv_c_gcc_w_float_equal)
 654 SOLANUM_C_GCC_TRY_FLAGS([-Wformat -Wformat-y2k -Wno-format-security], solanum_cv_c_gcc_w_format)
 655
 656 IRC_CFLAGS="$CFLAGS"
 657 ],[])
 658
 659 IRC_CFLAGS="$IRC_CFLAGS $CWARNS"
 660
 661 AC_SUBST(MODULES_LIBS)
 662 AC_SUBST(MOD_TARGET)
 663
 664 AC_SUBST(SSL_SRCS_ENABLE)
 665 AC_SUBST(SSL_INCLUDES)
 666 AC_SUBST(SSL_LIBS)
 667
 668 AC_SUBST(LDFLAGS)
 669 AC_SUBST(PICFLAGS)
 670 AC_SUBST(IRC_CFLAGS)
 671 AC_SUBST(SEDOBJ)
 672
 673
 674 if test "$prefix" = "NONE"; then
 675         AC_DEFINE_UNQUOTED(IRCD_PREFIX, "$ac_default_prefix", [Prefix where the ircd is installed.])
 676
 677 else
 678
 679 dnl Don't get bitten by Cygwin's stupidity if the user specified
 680 dnl a custom prefix with a trailing slash
 681
 682         prefix=`echo $prefix | sed 's/\/$//'`
 683         AC_DEFINE_UNQUOTED(IRCD_PREFIX, "$prefix", [Prefix where the ircd is installed.])
 684
 685 fi
 686
 687 AC_CONFIG_FILES(                        \
 688         Makefile                        \
 689         authd/Makefile                  \
 690         bandb/Makefile                  \
 691         ssld/Makefile                   \
 692         wsockd/Makefile                 \
 693         extensions/Makefile             \
 694         ircd/Makefile                   \
 695         modules/Makefile                \
 696         tests/Makefile                  \
 697         tools/Makefile                  \
 698         tools/genssl                    \
 699         doc/Makefile                    \
 700         help/Makefile                   \
 701 )
 702 AC_CONFIG_COMMANDS([tools/genssl_chmod], [chmod 755 tools/genssl])
 703
 704 AC_OUTPUT
 705
 706 if test "$cf_openssl_version_ok" = yes; then
 707         openssl="yes"
 708 else
 709         openssl="no"
 710 fi
 711
 712 echo "
 713 Configuration of ${BRANDING_NAME}-${BRANDING_VERSION}:
 714         Install directory  : $prefix
 715
 716         Ziplinks           : $zlib
 717         OpenSSL            : $openssl
 718         SCTP               : $sctp
 719
 720         Nickname length    : $NICKLEN
 721         Topic length       : $TOPICLEN
 722
 723 Use (g)make to compile $BRANDING_NAME, then (g)make install to install it.
 724 "