libratbox/configure.ac

   1 dnl $Id: configure.ac 25689 2008-07-10 17:13:27Z androsyn $
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl TODO: clean up all the OpenSSL and shared module checking stuff;
   5 dnl the most major changes have already been made and it looks like
   6 dnl said functions need to be just about as complex as they already are.
   7
   8 AC_PREREQ(2.60)
   9 AUTOMAKE_OPTIONS = 1.10
  10 dnl Sneaky way to get an Id tag into the configure script
  11 AC_COPYRIGHT([$Id: configure.ac 25689 2008-07-10 17:13:27Z androsyn $])
  12 AC_INIT([libratbox],[devel])
  13 AM_INIT_AUTOMAKE(AC_PACKAGE_TARNAME, AC_PACKAGE_VERSION, -)
  14
  15 AM_CONFIG_HEADER(include/libratbox_config.h)
  16
  17 AC_PREFIX_DEFAULT(/usr/local/libratbox)
  18 AC_GNU_SOURCE
  19
  20 dnl Checks for programs.
  21 AC_PROG_CC_C99
  22
  23 if test x"$ac_cv_prog_cc_c99" = "xno"; then
  24         AC_ERROR([ircd-ratbox requires a C99 capable compiler])
  25 fi
  26
  27
  28 AC_PROG_INSTALL
  29 AC_PROG_EGREP
  30 AC_PROG_SED
  31
  32 F77=no
  33 CXX=no
  34 GCJ=no
  35
  36 AM_DISABLE_STATIC
  37 AM_ENABLE_SHARED
  38 AM_MAINTAINER_MODE
  39
  40 AC_ISC_POSIX
  41 AC_C_INLINE
  42 AC_C_CONST
  43 AC_PROG_MAKE_SET
  44 AC_PROG_INSTALL
  45 AC_PATH_PROG(AUTOMAKE, automake)
  46 AC_PATH_PROG(ACLOCAL, aclocal)
  47 AC_PATH_PROG(AUTOHEADER, autoheader)
  48 AC_PATH_PROG(AS, as)
  49 AC_PATH_PROG(RM, rm)
  50 AC_PATH_PROG(CP, cp)
  51 AC_PATH_PROG(MV, mv)
  52 AC_PATH_PROG(LN, ln)
  53 AC_PATH_PROG(AR, ar)
  54 AC_PATH_PROG(LD, ld)
  55 AC_PATH_PROG(RANLIB, ranlib)
  56 AC_PATH_PROG(TOUCH, touch)
  57 AC_LANG(C)
  58
  59 AC_PROG_LIBTOOL
  60
  61 LIBTOOL="$LIBTOOL --silent"
  62
  63 AC_CONFIG_SUBDIRS(libltdl)
  64
  65
  66 case "$host_os" in
  67 *cygwin*)
  68      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
  69      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  70      ;;
  71 *mingw*)
  72      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
  73      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
  74      AC_CHECK_HEADER(windows.h, , [AC_MSG_ERROR([** MinGW and no windows.h.  I give up.])])
  75      AC_CHECK_HEADER(winsock2.h, , [AC_MSG_ERROR([** MinGW and no winsock2.h.  I give up.])])
  76      LIBS="$LIBS -lws2_32 -liphlpapi"
  77      is_mingw="yes"
  78      ;;
  79 *interix*)
  80      CPPFLAGS="$CFLAGS -D_ALL_SOURCE -D_XOPEN_SOURCE=500"
  81      ;;
  82 *solaris*|*sunos*)
  83      CPPFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_XPG4_2 -D__EXTENSIONS__"
  84      ;;
  85 *)
  86      ;;
  87 esac
  88
  89 AM_CONDITIONAL([MINGW], [test "$is_mingw" = "yes"])
  90
  91
  92 # backwards support for IRC_CFLAGS
  93 CFLAGS="$IRC_CFLAGS $CFLAGS -O0 -Wall"
  94
  95 dnl use directory structure of cached as default (hack)
  96 if test "$libexecdir" = '${exec_prefix}/libexec' &&
  97    test "$localstatedir" = '${prefix}/var'; then
  98         libexecdir='${bindir}'
  99         localstatedir='${prefix}'
 100 fi
 101
 102 AC_TYPE_PID_T
 103 AC_TYPE_SIZE_T
 104 AC_TYPE_SSIZE_T
 105 AC_TYPE_UID_T
 106
 107
 108 dnl Checks for header files.
 109 AC_HEADER_STDC
 110
 111 AC_CHECK_HEADERS([crypt.h unistd.h sys/socket.h sys/stat.h sys/time.h time.h netinet/in.h arpa/inet.h errno.h sys/uio.h spawn.h sys/poll.h sys/epoll.h sys/select.h sys/devpoll.h sys/event.h port.h signal.h sys/signalfd.h])
 112 AC_HEADER_TIME
 113
 114 dnl Networking Functions
 115 dnl ====================
 116
 117 AC_SEARCH_LIBS(socket, [socket],,)
 118
 119
 120 AC_CHECK_MEMBER([struct sockaddr.sa_len], [AC_DEFINE(SOCKADDR_IN_HAS_LEN, 1, [Define to 1 if sockaddr has a 'sa_len'
 121 member.])],,[[
 122 #ifdef HAVE_SYS_TYPES_H
 123 #include <sys/types.h>
 124 #endif
 125 #ifdef HAVE_SYS_SOCKET_H
 126 #include <sys/socket.h>
 127 #endif
 128 #ifdef HAVE_WINSOCK2_H
 129 #include <winsock2.h>
 130 #endif
 131 ]])
 132
 133 AC_CHECK_TYPE([socklen_t], rb_socklen_t=socklen_t,[
 134         AC_MSG_CHECKING([for socklen_t equivalent])
 135         AC_CACHE_VAL([rb_socklen_t],
 136         [
 137         # Systems have either "struct sockaddr *" or
 138         # "void *" as the second argument to getpeername
 139         rb_socklen_t=
 140         for arg2 in "struct sockaddr" void; do
 141                 for t in int size_t unsigned long "unsigned long"; do
 142                         AC_TRY_COMPILE([
 143 #include <sys/types.h>
 144 #include <sys/socket.h>
 145
 146 int getpeername (int, $arg2 *, $t *);
 147 ],[
 148 $t len;
 149 getpeername(0,0,&len);
 150 ],[
 151         rb_socklen_t="$t"
 152         break
 153 ])
 154                 done
 155         done
 156
 157         if test "x$rb_socklen_t" = x; then
 158                 AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
 159         fi
 160         ])
 161         AC_MSG_RESULT($rb_socklen_t)],
 162         [#include <sys/types.h>
 163 #include <sys/socket.h>])
 164
 165
 166
 167
 168
 169 AC_ARG_ENABLE(ipv6,AC_HELP_STRING([--disable-ipv6],[Disable IPv6 support]),[ipv6=$enableval],[ipv6=yes])
 170
 171 if test x$ipv6 != xyes; then
 172         have_v6="no"
 173 else
 174
 175 have_v6=yes
 176 RB_PROTO_INET6([], [
 177                 AC_MSG_NOTICE([Disabling IPv6 support: PF_INET6 not found])
 178                 have_v6=no
 179                 ])
 180
 181         if test "X$have_v6" = "Xyes"; then
 182         RB_TYPE_STRUCT_SOCKADDR_IN6([], [
 183                 AC_MSG_NOTICE([Disabling IPv6 support: struct sockaddr_in6 not found])
 184                 have_v6=no
 185                 ])
 186         fi
 187
 188 fi
 189
 190 AC_CHECK_TYPES([struct sockaddr_storage],[
 191         rb_have_sockaddr_storage=yes
 192         ],[], [
 193                 #include <sys/types.h>
 194                 #include <sys/socket.h>
 195         ])
 196
 197
 198 save_LIBS=$LIBS
 199 AC_SEARCH_LIBS(crypt, [crypt descrypt],,)
 200 LIBS=$save_LIBS
 201
 202 CRYPT_LIB=$ac_cv_search_crypt
 203
 204 if test "$CRYPT_LIB" = "none required"; then
 205         unset CRYPT_LIB
 206 elif test "$CRYPT_LIB" = no; then
 207         need_crypt=yes;
 208         AC_DEFINE(NEED_CRYPT, 1, [Define if your system needs crypt.])
 209         unset CRYPT_LIB
 210 fi
 211
 212 AM_CONDITIONAL([NEED_CRYPT], [test x"$need_crypt" = "xyes"])
 213
 214
 215 AC_SUBST(CRYPT_LIB)
 216
 217 dnl Check for stdarg.h - if we cant find it, halt configure
 218 AC_CHECK_HEADER(stdarg.h, , [AC_MSG_ERROR([** stdarg.h could not be found - libratbox will not compile without it **])])
 219
 220 AC_CHECK_TYPE([sa_family_t], [],
 221 [AC_DEFINE(sa_family_t, [u_int16_t], [If system does not define sa_family_t, define it here.])],
 222 [[#include <sys/types.h>
 223 #include <sys/socket.h>]])
 224
 225
 226 dnl check for various functions...
 227 AC_CHECK_FUNCS([socketpair gettimeofday writev sendmsg gmtime_r strtok_r usleep posix_spawn strlcpy strlcat strnlen fstat signalfd select poll kevent port_create epoll_ctl arc4random getrusage])
 228
 229 AC_SEARCH_LIBS(nanosleep, rt posix4, AC_DEFINE(HAVE_NANOSLEEP, 1, [Define if you have nanosleep]))
 230 AC_SEARCH_LIBS(timer_create, rt, AC_DEFINE(HAVE_TIMER_CREATE, 1, [Define if you have timer_create]))
 231 RB_CHECK_TIMER_CREATE
 232
 233 AC_FUNC_ALLOCA
 234 AC_FUNC_VFORK
 235 AC_FUNC_MMAP
 236
 237 AC_MSG_CHECKING(for /dev/poll)
 238 if test -c "/dev/poll"; then
 239         AC_MSG_RESULT(yes)
 240         AC_DEFINE(HAVE_DEVPOLL, [1], [Define to 1 if you have devpoll])
 241 else
 242         AC_MSG_RESULT(no)
 243 fi
 244
 245
 246 if test "$is_mingw" = "yes"; then
 247         AC_DEFINE(HAVE_WIN32, [1], [Define to 1 if you are on windows])
 248 fi
 249
 250
 251 dnl OpenSSL support
 252 AC_MSG_CHECKING(for OpenSSL)
 253 AC_ARG_ENABLE(openssl,
 254 [AC_HELP_STRING([--enable-openssl[=DIR]],[Enable OpenSSL support (DIR optional).])
 255 AC_HELP_STRING([--disable-openssl],[Disable OpenSSL support.])],
 256 [cf_enable_openssl=$enableval],
 257 [cf_enable_openssl="auto"])
 258
 259 if test "$cf_enable_openssl" != "no" ; then
 260         cf_openssl_basedir=""
 261         if test "$cf_enable_openssl" != "auto" &&
 262         test "$cf_enable_openssl" != "yes" ; then
 263                 dnl Support for --enable-openssl=/some/place
 264                 cf_openssl_basedir="`echo ${cf_enable_openssl} | sed 's/\/$//'`"
 265         else
 266         dnl Do the auto-probe here.  Check some common directory paths.
 267                 for dirs in /usr/local/ssl /usr/pkg /usr/local \
 268                 /usr/local/openssl ; do
 269                         if test -f "${dirs}/include/openssl/opensslv.h" ; then
 270                                 cf_openssl_basedir="${dirs}"
 271                         break
 272                         fi
 273                 done
 274                 unset dirs
 275         fi
 276         dnl Now check cf_openssl_found to see if we found anything.
 277         if test ! -z "$cf_openssl_basedir"; then
 278                 if test -f "${cf_openssl_basedir}/include/openssl/opensslv.h" ; then
 279                         SSL_CFLAGS="-I${cf_openssl_basedir}/include"
 280                         SSL_LIBS="-L${cf_openssl_basedir}/lib"
 281                 else
 282                 dnl OpenSSL wasn't found in the directory specified.  Naughty
 283                 dnl administrator...
 284                 cf_openssl_basedir=""
 285                 fi
 286         else
 287         dnl Check for stock FreeBSD 4.x and 5.x systems, since their files
 288         dnl are in /usr/include and /usr/lib.  In this case, we don't want to
 289         dnl change INCLUDES or LIBS, but still want to enable OpenSSL.
 290         dnl We can't do this check above, because some people want two versions
 291         dnl of OpenSSL installed (stock FreeBSD 4.x/5.x and /usr/local/ssl)
 292         dnl and they want /usr/local/ssl to have preference.
 293                 if test -f "/usr/include/openssl/opensslv.h" ; then
 294                         cf_openssl_basedir="/usr"
 295                 fi
 296         fi
 297
 298         dnl If we have a basedir defined, then everything is okay.  Otherwise,
 299         dnl we have a problem.
 300         if test ! -z "$cf_openssl_basedir"; then
 301                 AC_MSG_RESULT($cf_openssl_basedir)
 302                 cf_enable_openssl="yes"
 303         else
 304                 AC_MSG_RESULT([not found. Specify a correct path?])
 305                 cf_enable_openssl="no"
 306         fi
 307         unset cf_openssl_basedir
 308 else
 309         dnl If --disable-openssl was specified
 310         AC_MSG_RESULT(disabled)
 311 fi
 312
 313 save_CPPFLAGS="$CPPFLAGS"
 314 CPPFLAGS="$CPPFLAGS $SSL_CFLAGS"
 315 save_LIBS="$LIBS"
 316 LIBS="$LIBS $SSL_LIBS"
 317 if test "$cf_enable_openssl" != no; then
 318         dnl Check OpenSSL version (must be 0.9.7 or above!)
 319         AC_MSG_CHECKING(for OpenSSL 0.9.7 or above)
 320         AC_RUN_IFELSE(
 321                 AC_LANG_PROGRAM(
 322                 [#include <openssl/opensslv.h>
 323                 #include <stdlib.h>],
 324                 [[if (OPENSSL_VERSION_NUMBER >= 0x00907000)
 325                 exit(0); else exit(1);]]),
 326         cf_enable_openssl=yes,
 327         cf_enable_openssl=no,
 328         cf_enable_openssl=no)
 329
 330         if test "$cf_enable_openssl" != no; then
 331                 AC_MSG_RESULT(found)
 332         else
 333                 AC_MSG_RESULT(no - OpenSSL support disabled)
 334         fi
 335
 336 fi
 337
 338
 339 if test "$cf_enable_openssl" != no; then
 340         CPPFLAGS="$CPPFLAGS $SSL_LIBS"
 341         AC_CHECK_LIB(crypto, RAND_status,
 342                 [cf_enable_openssl=yes],
 343                 [cf_enable_openssl=no])
 344 fi
 345
 346
 347 if test "$cf_enable_openssl" != no; then
 348         CPPFLAGS="$CPPFLAGS $SSL_LIBS"
 349         AC_CHECK_LIB(ssl, SSL_read,
 350                 [SSL_LIBS="-lssl -lcrypto"],
 351                 [cf_enable_openssl=no], [-lcrypto])
 352 fi
 353
 354
 355
 356 dnl GnuTLS support
 357 AC_MSG_CHECKING(for GnuTLS)
 358 AC_ARG_ENABLE(gnutls,
 359 [AC_HELP_STRING([--enable-gnutls],[Enable GnuTLS support.])
 360 AC_HELP_STRING([--disable-gnutls],[Disable GnuTLS support.])],
 361 [cf_enable_gnutls=$enableval],
 362 [cf_enable_gnutls="auto"])
 363
 364 if test "$cf_enable_gnutls" != no; then
 365        PKG_CHECK_MODULES(GNUTLS, [gnutls], [
 366                cf_enable_gnutls="yes"
 367        ], [cf_enable_gnutls="no"])
 368 fi
 369
 370 if test "$cf_enable_gnutls" = "auto" -a "$cf_enable_openssl" = "yes"; then
 371        cf_enable_gnutls="no"
 372 fi
 373
 374 if test x"$cf_enable_openssl" != xno; then
 375         AC_DEFINE(HAVE_OPENSSL,1,[Has OpenSSL])
 376         GNUTLS_CFLAGS=""
 377         GNUTLS_LIBS=""
 378         SSL_TYPE="openssl"
 379 elif test x"$cf_enable_gnutls" != xno; then
 380         AC_DEFINE(HAVE_GNUTLS, 1, [Has GnuTLS])
 381         SSL_LIBS=""
 382         SSL_CFLAGS=""
 383         SSL_TYPE="gnutls"
 384 fi
 385
 386
 387
 388
 389 CPPFLAGS="$save_CPPFLAGS"
 390 LIBS="$save_LIBS"
 391
 392 dnl End OpenSSL detection
 393
 394
 395
 396
 397 dnl Debug-related options
 398 dnl =====================
 399
 400 AC_ARG_ENABLE(assert,
 401 AC_HELP_STRING([--enable-assert],[Enable assert(). Choose between soft(warnings) and hard(aborts the daemon)]),
 402 [assert=$enableval], [assert=no])
 403
 404 if test "$assert" = no; then
 405         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 406 elif test "$assert" = soft; then
 407         AC_DEFINE(SOFT_ASSERT, 1, [Define this to enable soft asserts.])
 408         AC_DEFINE(NDEBUG, 1, [Define this to disable debugging support.])
 409 elif test "$assert" = yes; then
 410         assert = "hard";
 411 fi
 412
 413 AC_MSG_CHECKING(if you want to do a profile build)
 414 AC_ARG_ENABLE(profile,
 415 AC_HELP_STRING([--enable-profile],[Enable profiling]),
 416 [profile=$enableval], [profile=no])
 417
 418 if test "$profile" = yes; then
 419         if test "$ac_cv_c_compiler_gnu" = yes; then
 420                 CFLAGS="$CFLAGS -pg -static"
 421                 AC_MSG_RESULT([yes, adding -pg -static])
 422                 AC_DEFINE(RATBOX_PROFILE, 1, [Defined to mark profiling is enabled])
 423         else
 424                 AC_MSG_RESULT([no, profile builds only work with gcc])
 425         fi
 426 else
 427         AC_MSG_RESULT(no)
 428 fi
 429
 430 AC_ARG_ENABLE(balloc,
 431 AC_HELP_STRING([--disable-balloc],[Disable the block allocator.]),
 432 [balloc=$enableval], [balloc=yes])
 433
 434 if test "$balloc" = no; then
 435         AC_DEFINE([NOBALLOC], 1, [Define to 1 if you wish to disable the block allocator.])
 436 fi
 437
 438 AC_ARG_ENABLE(warnings,
 439 AC_HELP_STRING([--enable-warnings],[Enable all sorts of warnings for debugging.]),
 440 [CFLAGS="$CFLAGS -Wall -Werror -Wcast-qual -Wmissing-declarations -Wmissing-prototypes -Wnested-externs -Wshadow -Wwrite-strings -W -Wno-unused -Wunused-function -Wunused-variable"],[])
 441
 442 AC_SUBST(LDFLAGS)
 443 AC_SUBST(PICFLAGS)
 444 AC_SUBST(CFLAGS)
 445 AC_SUBST(SEDOBJ)
 446 AC_SUBST(SSL_CFLAGS)
 447 AC_SUBST(SSL_LIBS)
 448 AC_SUBST(GNUTLS_CFLAGS)
 449 AC_SUBST(GNUTLS_LIBS)
 450
 451 if test "$prefix" = "NONE"; then
 452         AC_DEFINE_UNQUOTED(RB_PREFIX, "$ac_default_prefix", [Prefix where libratbox is installed.])
 453
 454 else
 455
 456 dnl Don't get bitten by Cygwin's stupidity if the user specified
 457 dnl a custom prefix with a trailing slash
 458
 459         prefix=`echo $prefix | sed 's/\/$//'`
 460         AC_DEFINE_UNQUOTED(RB_PREFIX, "$prefix", [Prefix where libratbox is installed.])
 461
 462 fi
 463
 464 AC_SUBST(RB_PREFIX)
 465
 466 AC_CONFIG_COMMANDS([include/librb-config.h],
 467 [
 468         outfile=include/librb-config.h.tmp
 469         cat > $outfile  <<\_______EOF
 470 /*
 471  * librb-config.h: libratbox config file. Please modify configure.ac
 472  */
 473
 474 #ifndef __LIBRB_CONFIG_H
 475 #define __LIBRB_CONFIG_H
 476
 477 _______EOF
 478
 479 if test "x$rb_have_ipv6" = "xyes"; then
 480         echo "#define RB_IPV6 1" >> $outfile
 481 fi
 482
 483 if test "x$rb_windows_h" = "xyes"; then
 484         echo '#define WIN32_LEAN_AND_MEAN 1' >> $outfile
 485         echo '#include <windows.h>' >> $outfile
 486         echo '#include <winsock2.h>' >> $outfile
 487         echo '#include <iphlpapi.h>' >> $outfile
 488 fi
 489
 490 if test "x$rb_alloca_h" = "xyes"; then
 491         echo '#define RB_HAVE_ALLOCA_H 1' >> $outfile
 492 fi
 493
 494 if test "x$rb_header_stdc" = "xyes"; then
 495         echo '#include <stdlib.h>' >> $outfile
 496         echo '#include <stddef.h>' >> $outfile
 497 elif test "x$rb_header_stdlib" = "xyes"; then
 498         echo '#include <stdlib.h>' >> $outfile
 499 fi
 500
 501 if test "x$rb_header_string_h" = "xyes"; then
 502         echo '#include <string.h>' >> $outfile
 503 fi
 504
 505 if test "x$rb_stdint_h" = "xyes"; then
 506         echo '#include <stdint.h>' >> $outfile
 507 fi
 508
 509 if test "x$rb_inttypes_h" = "xyes"; then
 510         echo '#include <inttypes.h>' >> $outfile
 511 fi
 512
 513 if test "x$rb_sys_types_h" = "xyes"; then
 514         echo '#include <sys/types.h>' >> $outfile
 515 fi
 516 if test "x$rb_sys_time_h" = "xyes"; then
 517         echo '#include <sys/time.h>' >> $outfile
 518 fi
 519 if test "x$rb_sys_stat_h" = "xyes"; then
 520         echo '#include <sys/stat.h>' >> $outfile
 521 fi
 522 if test "x$rb_time_h" = "xyes"; then
 523         echo '#include <time.h>' >> $outfile
 524 fi
 525
 526 if test "x$rb_sys_socket_h" = "xyes"; then
 527         echo '#include <sys/socket.h>' >> $outfile
 528 fi
 529
 530 if test "x$rb_netinet_in_h" = "xyes"; then
 531         echo '#include <netinet/in.h>' >> $outfile
 532 fi
 533
 534 if test "x$rb_arpa_inet_h" = "xyes"; then
 535         echo '#include <arpa/inet.h>' >> $outfile
 536 fi
 537
 538 if test "x$rb_unistd_h" = "xyes"; then
 539         echo '#include <unistd.h>' >> $outfile
 540 fi
 541
 542 if test "x$rb_crypt_h" = "xyes"; then
 543         echo '#include <crypt.h>' >> $outfile
 544 fi
 545
 546 if test "x$rb_errno_h" = "xyes"; then
 547         echo '#include <errno.h>' >> $outfile
 548 fi
 549
 550 echo "typedef $rb_socklen_t rb_socklen_t;" >> $outfile
 551
 552
 553 if test "x$rb_sockaddr_sa_len" = "xyes"; then
 554         echo '#define RB_SOCKADDR_HAS_SA_LEN 1' >> $outfile
 555 fi
 556
 557 if test "x$rb_sockaddr_storage" = "xyes"; then
 558         echo '#define rb_sockaddr_storage sockaddr_storage' >> $outfile
 559 else
 560         echo 'struct rb_sockaddr_storage { uint8_t _padding[128]; };' >> $outfile
 561 fi
 562
 563 cat >> $outfile <<\_______EOF
 564 #endif /* __LIBRB_CONFIG_H */
 565 _______EOF
 566
 567 if cmp -s $outfile include/librb-config.h; then
 568         AC_MSG_NOTICE([include/librb-config.h is unchanged])
 569         ${rb_rm} -f $outfile
 570 else
 571         ${rb_mv} $outfile include/librb-config.h
 572 fi
 573
 574 ],[
 575         if test x$ac_cv_header_stdc = xyes; then
 576                 rb_header_stdc=yes
 577         fi
 578         if test x$ac_cv_header_stdlib_h = xyes; then
 579                 rb_header_stdlib_h=yes
 580         fi
 581         if test x$ac_cv_header_string_h = xyes; then
 582                 rb_header_string_h=yes
 583         fi
 584         if test x$ac_cv_header_memory_h = xyes; then
 585                 rb_header_memory_h=yes
 586         fi
 587         if test "x${ac_cv_working_alloca_h+set}" = xset ; then
 588                 rb_alloca_h="$ac_cv_working_alloca_h"
 589         else
 590                 rb_alloc_h="$ac_cv_header_alloca_h"
 591         fi
 592         if test x$ac_cv_member_struct_sockaddr_sa_len = xyes; then
 593                 rb_sockaddr_sa_len=yes
 594         fi
 595         if test x$ac_cv_header_sys_socket_h = xyes; then
 596                 rb_sys_socket_h=yes
 597         fi
 598         if test x$ac_cv_header_sys_types_h = xyes; then
 599                 rb_sys_types_h=yes
 600         fi
 601         if test x$ac_cv_header_sys_stat_h = xyes; then
 602                 rb_sys_stat_h=yes
 603         fi
 604         if test x$ac_cv_header_sys_time_h = xyes; then
 605                 rb_sys_time_h=yes
 606         fi
 607         if test x$ac_cv_header_time = xyes; then
 608                 rb_time_h=yes
 609         fi
 610
 611         if test x$ac_cv_header_stdint_h = xyes; then
 612                 rb_stdint_h=yes
 613         fi
 614         if test x$ac_cv_header_inttypes_h = xyes; then
 615                 rb_inttypes_h=yes
 616         fi
 617         if test x$ac_cv_header_netinet_in_h = xyes; then
 618                 rb_netinet_in_h=yes
 619         fi
 620
 621         if test x$ac_cv_header_crypt_h = xyes; then
 622                 rb_crypt_h=yes
 623         fi
 624         if test x$ac_cv_header_errno_h = xyes; then
 625                 rb_errno_h=yes
 626         fi
 627         if test x$ac_cv_header_unistd_h = xyes; then
 628                 rb_unistd_h=yes
 629         fi
 630         if test x$ac_cv_header_windows_h = xyes; then
 631                 rb_windows_h=yes
 632         fi
 633         if test x$ac_cv_header_winsock2_h = xyes; then
 634                 rb_winsock2_h=yes
 635         fi
 636
 637         rb_socklen_t=$rb_socklen_t
 638
 639         if test "x$rb_have_sockaddr_storage" = "xyes"; then
 640                 rb_sockaddr_storage="yes"
 641         else
 642                 rb_sockaddr_storage="no"
 643         fi
 644
 645         rb_have_ipv6="$have_v6"
 646
 647         rb_mv="$MV"
 648         rb_rm="$RM"
 649
 650 ]
 651
 652
 653 )
 654
 655
 656 AC_CONFIG_FILES(                \
 657         src/Makefile            \
 658         Makefile                \
 659         libratbox.pc            \
 660 )
 661
 662 AC_OUTPUT
 663
 664 dnl Make it look sexay!
 665
 666 echo
 667 echo "Compiling $PACKAGE_NAME $PACKAGE_VERSION"
 668 echo
 669
 670 echo "Installing into: $prefix"
 671
 672 echo "IPv6 support ................... $have_v6"
 673 echo "Assert debugging ............... $assert"
 674 echo "Block allocator ................ $balloc"
 675 echo "SSL Type........................ $SSL_TYPE"
 676 echo
 677